「达摩院MindOpt APL 建模语言」语法说明 print 将结果写表格文件

# 覆盖式样写csv文件
print "{}, {}, {}" % "日期", "班次", "员工编号" : "file.csv";
close "file.csv";
# append追加式样写csv文件
print "{}, {}, {}" % d,s,e >> "Schedule_Results.csv";
close "Schedule_Results.csv";

clear model;
set Schedule = {read "班次.csv" as "<1s>" skip 1}; # 读取班次的名称
set Day = {read "需求人数.csv" as "<1n>" skip 1}; #读取排班的日期
param maxDay = max(Day);
print "待排",maxDay,"天的班";
param NumDemand = read "需求人数-长列表.csv" as "<1n,2s> 3n" skip 1; #读取每天各个班次的需求人数，原横纵表拉成长列表为了读取数据方便
param totalSlots = sum {<d,s> in Day*Schedule} NumDemand[d,s];
print "总共有",totalSlots,"个班次待排";
#预估上班人数
param maxEmployee = ceil(totalSlots/5) + 1; #如果班次需求特殊导致不可解的时候，可以增加员工
print "设置参与排班人数：",maxEmployee;
set Employee = {1..maxEmployee};
#声明变量 
var x[Day*Schedule*Employee] binary; 
#约束
subto constraint_0 :
    forall {<d,s> in Day*Schedule}
         sum {e in Employee} x[d,s,e] >= NumDemand[d,s]; #满足用工需求
subto constraint_1 : 
    forall {<d,e> in Day*Employee}
            sum {s in Schedule} x[d,s,e] <= 1;  #每人每天只排一个班次
set DayPre = Day without {<maxDay>}; #去掉最后一天
subto constraint_2 : 
    forall {e in Employee}
        forall {d in DayPre}
            x[d,"夜班0-8点",e] + x[d+1,"早班8-16点",e] <= 1; #前一天晚班的，第二天不排早班
subto constraint_3 : 
    forall {e in Employee}
        sum {<d,s> in Day*Schedule} x[d,s,e] <= 5; #待排的7天里只上5天班
minimize minOnduty: sum {<d,s,e> in Day*Schedule*Employee} x[d,s,e];
#求解
option solver mindopt;     # （可选）指定求解用的求解器，默认是MindOpt
option mindopt_options 'print=0'; #设置求解器输出级别，减少过程打印
solve;         # 求解
# 结果打印和检查结果
print "-----------------Display---------------";
#display; #打印太多，注释了
# 将结果打印为数据表格
print "{}, {}, {}" % "日期", "班次", "员工编号" : "Schedule_Results.csv";
close "Schedule_Results.csv";
forall {<d,s,e> in Day*Schedule*Employee with x[d,s,e] >0}
    print "{}, {}, {}" % d, s,e >> "Schedule_Results.csv";
close "Schedule_Results.csv";

待排7天的班
总共有99个班次待排
设置参与排班人数：21
Running mindoptampl
wantsol=1
print=0
MindOpt Version 1.0.0 (Build date: 20231013)
Copyright (c) 2020-2023 Alibaba Cloud.
Start license validation (current time : 17-NOV-2023 16:52:20).
License validation terminated. Time : 0.004s
OPTIMAL; objective 99.00
Completed.

print "{},{},{} "% "起点","途径点","商品数量" : "Results.csv";
close "Results.csv";
forall {<i, j> in LINKS}
    print "{},{},{}" % i,j,Ship[i,j]  >> "Results.csv";
close "Results.csv";

print "{}, {}, {}, {}" % "油脂", "月份", "处理方案","数量" : "每月油脂处理方式.csv";
close "每月油脂处理方式.csv";
forall {<j,m,n> in O*M*N}
    print "{}, {}, {}, {}" % j, m, n, x[j,m,n] >> "每月油脂的处理方式.csv";
close "每月油脂处理方式.csv";
print "{}, {}" % "月份", "生产计划" : "Results_.csv";
close "Results_.csv";
forall {<m> in M}
    print "{}, {}" % m,y[m] >> "Results_.csv";
close "Results_.csv";