LabVIEW Arduino无线蓝牙遥控智能车（项目篇—2）

#define forward_command   0x00   //前进命令
#define back_command      0x10   //后退命令
#define left_command       0x20   //左转命令
#define right_command      0x30   //右转命令
#define stop_command      0x40   //停止命令
#define speed_1           0x50   //低速命令
#define speed_2           0x60   //中低速命令
#define speed_3           0x70   //中速命令
#define speed_4           0x80   //中高速命令
#define speed_5           0x90   //高速命令
byte comdata[3]={0};   //定义数组数据，用于存放串口命令数据
int flag = 0;           //遥控/自动标志位，默认为遥控模式
int INA1 = 7;
int INB1 = 6;
int PWM1 = 5;      //定义电机1的转向和速度的控制引脚
int INA2 = 4;
int INB2 = 2;
int PWM2 = 3;      //定义电机2的转向和速度的控制引脚
int Trace_sensor_X1=8;
int Trace_sensor_X2=9;
int Trace_sensor_Y1=10;
int Trace_sensor_Y2=11;      //定义四个红外循迹传感器的引脚
int Avoidance_sensor=12;     //定义红外避障传感器的引脚
void receive_data(void);      //接收串口命令数据
void test_do_data(void);      //测试串口命令数据是否正确，并执行命令
void forward(void);        //前进子函数
void back(void);           //后退子函数
void turn_Left(void);       //左转子函数
void turn_Right(void);       //右转子函数
void stop_car(void);             //停止子函数
void Automatic_mode(void);      //自动模式子函数
void setup()
{
  Serial.begin(9600);             //初始化串口波特率为9600
  pinMode(INA1, OUTPUT);
  pinMode(INB1, OUTPUT);
  pinMode(PWM1, OUTPUT);      //设置电机1的控制引脚为输出状态
  pinMode(INA2, OUTPUT);
  pinMode(INB2, OUTPUT);
  pinMode(PWM2, OUTPUT);      //设置电机2的控制引脚为输出状态
  pinMode(Trace_sensor_X1, INPUT);
  pinMode(Trace_sensor_X2, INPUT);
  pinMode(Trace_sensor_Y1, INPUT);
  pinMode(Trace_sensor_Y2, INPUT); //设置红外循迹传感器的控制引脚为输入状态
  pinMode(Avoidance_sensor,INPUT); //设置红外避障传感器的控制引脚为输入状态
  analogWrite(PWM1,150); //left motor
  analogWrite(PWM2,150); //ringt motor    //将电机速度设置为中速档位
}
void loop()
{
  if (Serial.available() > 0)      //不断检测串口是否有数据
   {
        receive_data();            //从串口缓冲区接收串口命令数据
        test_do_data();            //测试串口命令数据是否正确并执行命令
   }
   if(flag==1)            //判断是否为自动模式状态
   { 
  Automatic_mode();                 //执行自动模式
  analogWrite(PWM1,150); //left motor 
  analogWrite(PWM2,150); //ringt motor     //将电机速度切换至中速档位
   }
}
void receive_data(void)   //从串口缓冲区接收串口命令数据
{
   int i ;
   for(i=0;i<3;i++)   //命令长度为3个字节，每次读取3个字节
   {
      comdata[i] =Serial.read();   //读取一个字节的数据
      //延时一会，让串口缓存准备好下一个字节，不延时可能会导致数据丢失，
       delay(2);
   }
}
void test_do_data(void)      //测试串口命令数据是否正确并执行命令
{
  if(comdata[0] == 0x55)            //0x55为命令帧头，判断帧头是否正确
   {
     if(comdata[1] == 0xAA)        //0xAA为遥控模式命令
     {
  flag=0;               //切换至遥控模式
         switch (comdata[2])         //匹配遥控模式中的具体命令
          {
            case forward_command:      //前进命令
                 forward();
                 break;
            case back_command:         //后退命令
           back();
                 break ;
            case left_command:          //左转命令
           turn_Left();
                 break ;
            case right_command:         //右转命令
           turn_Right();
                 break ;
            case stop_command:         //停止命令
           stop_car();
                 break ;
      case speed_1:               //低速命令
           analogWrite(PWM1,50);
           analogWrite(PWM2,50);  
                 break;
            case speed_2:                //右转命令
           analogWrite(PWM1,100); 
           analogWrite(PWM2,100); 
                 break ;
            case speed_3:                //右转命令
     analogWrite(PWM1,150); 
     analogWrite(PWM2,150); 
                 break ;
            case speed_4:                //右转命令
     analogWrite(PWM1,200); 
     analogWrite(PWM2,200); 
                 break ;
      case speed_5:                //右转命令
           analogWrite(PWM1,250);
     analogWrite(PWM2,250); 
                 break ;
          }             
       }
      if(comdata[1] == 0xFF)        //0xFF为自主模式命令
      {
        flag=1;               //切换至自主模式
        comdata[2] = 0;               //清空命令数据
      }
   }
}
void Automatic_mode(void)     //自主模式，循迹和避障
{
  int State_value=0;
  if(digitalRead(Avoidance_sensor)==0)   //避障功能，有障碍物则后退左转
  {
    back();
    delay(1000);
    turn_Left();
    delay(500);
  }
  //读取红外循迹传感器组的状态
  State_value=digitalRead(Trace_sensor_X2)*8+digitalRead(Trace_sensor_X1)*4+digitalRead(Trace_sensor_Y1)*2+digitalRead(Trace_sensor_Y2);
  switch (State_value)     //匹配状态，并调整位置
        {
            case 8:               //大幅度偏左，大角度右转
    turn_Right();
    delay(200);
                   break;
            case 4:               //小幅度偏左，小角度右转
    turn_Right();     
    delay(100);
                   break ;
            case 2:               //小幅度偏右，小角度左转
    turn_Left();
    delay(100);
                   break ;
            case 1:               //大幅度偏右，大角度左转
    turn_Left();
    delay(200);
                   break ;
            default:               //其他状态，前进
    forward();
    break;
          }   
}
void forward(void)    //前进
{
  digitalWrite(INA1, LOW); 
  digitalWrite(INB1, HIGH); 
  digitalWrite(INA2, LOW); 
  digitalWrite(INB2, HIGH); 
}
void back(void)    //后退
{
  digitalWrite(INA1, HIGH); 
  digitalWrite(INB1, LOW); 
  digitalWrite(INA2, HIGH); 
  digitalWrite(INB2, LOW); 
}
void turn_Left(void)    //左转
{
  digitalWrite(INA1, LOW); 
  digitalWrite(INB1, HIGH); 
  digitalWrite(INA2, HIGH); 
  digitalWrite(INB2, LOW); 
}
void turn_Right(void)    //右转
{
  digitalWrite(INA1, HIGH); 
  digitalWrite(INB1, LOW); 
  digitalWrite(INA2, LOW); 
  digitalWrite(INB2, HIGH); 
}
void stop_car(void)    //停止
{
  digitalWrite(INA1, LOW); 
  digitalWrite(INB1, LOW); 
  digitalWrite(INA2, LOW); 
  digitalWrite(INB2, LOW); 
}