开源播放器CicadaPlayer单元测试之Googletest和cmake

CicadaPlayer在Mac和Linux下使用Googletest结合cmake进行单元测试，并且可以在Travis服务器上进行单元测试，下面我们就来介绍一下如何实现

使用cmake整合googletest

首先呢，我们需要“安装”Googletest，这里呢，我们直接使用cmake的FetchContent功能，直接使用，无需手动安装

我们可以建立一个cmake文件，比如GoogleTest.cmake

此文件参考cmake-cookbook为了工程上使用方便，我做了一下提炼

include(FetchContent)

FetchContent_Declare(
        googletest
        GIT_REPOSITORY https://github.com/google/googletest.git
        GIT_TAG release-1.8.0
)

FetchContent_GetProperties(googletest)

if (NOT googletest_POPULATED)
    FetchContent_Populate(googletest)

    # Prevent GoogleTest from overriding our compiler/linker options
    # when building with Visual Studio
    set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
    # Prevent GoogleTest from using PThreads
    set(gtest_disable_pthreads ON CACHE BOOL "" FORCE)

    # adds the targers: gtest, gtest_main, gmock, gmock_main
    add_subdirectory(
            ${googletest_SOURCE_DIR}
            ${googletest_BINARY_DIR}
    )

    # Silence std::tr1 warning on MSVC
    if (MSVC)
        foreach (_tgt gtest gtest_main gmock gmock_main)
            target_compile_definitions(${_tgt}
                    PRIVATE
                    "_SILENCE_TR1_NAMESPACE_DEPRECATION_WARNING"
                    )
        endforeach ()
    endif ()
endif ()

set(CMAKE_CXX_FLAGS "-fprofile-instr-generate -fcoverage-mapping")

引用googletest

在需要使用的地方直接

include(GoogleTest.cmake)

就可以了，而一般情况下一个工程都会有很多的单元测试，一般的做法呢，我们创建一个根CMakeLists文件，在这个根CMakeLists文件中引用这个Googletest.cmake文件即可，如

...
include(GoogleTest.cmake)
add_subdirectory(dataSource)
#add_subdirectory(render)
add_subdirectory(demuxer)
add_subdirectory(decoder)
...

这样每个子目录下的测试文件都可以直接使用googletest了

如

...
enable_testing()

add_test(
        NAME dataSourceTest
        COMMAND $<TARGET_FILE:dataSourceTest>
)
...

这样就添加了一个单元测试

为ctest优化CMakeLists

如果你在每个子目录的CMakeLists中添加自己的单元测试，当然是没有问题，这样的好处是，在你新添加子目录后，只需要在这个根CMakeLists中 add_subdirectory就可以了，不需要其他修改。但是如果你准备使用ctest做单元测试，那么你就需要先进入每一个子目录下，然后再执行，如果执行完单元测试后还需要做些别的，如覆盖率统计，那么整个流程就比较复杂了。并且最麻烦的是不能多任务执行了。

我在这里选的是另外一种方法，add_test写在根CMakeLists中，这样在这个根目录下执行ctest就可以了，并且支持多任务并行执行

可参考CMakeLists.txt

project(frameworkUintTest)
cmake_minimum_required(VERSION 3.15)


include(GoogleTest.cmake)
add_subdirectory(dataSource)
#add_subdirectory(render)
add_subdirectory(demuxer)
add_subdirectory(decoder)

enable_testing()

add_test(
        NAME dataSourceTest
        COMMAND $<TARGET_FILE:dataSourceTest>
)

#add_test(
#        NAME renderTest
#        COMMAND $<TARGET_FILE:renderTest>
#)

add_test(
        NAME demuxerUnitTest
        COMMAND $<TARGET_FILE:demuxerUnitTest>
)

add_test(
        NAME decoderUnitTest
        COMMAND $<TARGET_FILE:decoderUnitTest>
)

如在Travis服务器上

https://github.com/alibaba/CicadaPlayer/blob/develop/.travis.yml

  - cd mediaPlayer/tests/
  - ctest -j8 --output-on-failure

如此就可以了