开发者社区> 杨俊明> 正文

AS3中的单件(Singleton)模式

简介: 单件(singleton)模式在c#中是最容易实现的模式,其主要用意就在于限制使用者用new来创建多个实例。但在as3中,构造函数必须是public的(语法本身要求的),而且也不能在构造函数中抛出异常(编译可通过,但是逻辑行不通),因为这样相当于把创建实例的路子完全切断了,一个实例也得不到! 错误...
+关注继续查看

单件(singleton)模式在c#中是最容易实现的模式,其主要用意就在于限制使用者用new来创建多个实例。但在as3中,构造函数必须是public的(语法本身要求的),而且也不能在构造函数中抛出异常(编译可通过,但是逻辑行不通),因为这样相当于把创建实例的路子完全切断了,一个实例也得不到!

错误代码:

package{
	public class singleton{
		
		static private var _instance:singleton;
		
		public function singleton():void{
			throw Error("单件模式不能用new创建实例!");
		}
		
		public static function getInstance():singleton{
			if (_instance==null){
				_instance = new singleton();//因为上面的构造函数抛出了异常,所以这里运行时会报错
			}
			return _instance;
		} 
			
	}
}

怎样即能创建实例,又阻止使用者调用构造函数呢?这里要用到as3的一个特性:默认情况下,一个as文件,只能放一个类,而且必须用package声明,但有一种特殊情况:一个as文件中定义二个类,一个用package声明,一个不用!没有package的类,默认访问范围为“仅同在一个文件的类可访问”

package
{

	public class SingletonFactory
	{
		private static var _instance:Singleton2=null;

		public function SingletonFactory():void
		{
			trace Error("error!");
		}

		public static function getInstance():Singleton2
		{
			if (_instance == null)
			{
				_instance=new Singleton2();
			}
			return _instance;
		}
	}
}

class Singleton2
{
	import flash.utils.getTimer;

	private var _createTime:uint;

	public function Singleton2()
	{
		_createTime=getTimer();
	}

	public function toString():String
	{
		return "本实例的创建时间:" + _createTime.toString();
	}

	public function helloWorld(name:String):String
	{
		return "hello " + name + " !";
	}
}

测试:

package
{
	import flash.display.Sprite;
	import flash.utils.getTimer;
	
	public class main extends Sprite
	{
		public function main()
		{			
			var a:* = SingletonFactory.getInstance();
			trace(getTimer());
			
			var s1:* = SingletonFactory.getInstance();
			trace(s1.toString());
			
			//空循环,刻意占用cpu,消耗占时间而已
			for(var i:uint=0;i<999999;i++)
			{
				//trace();
			}
			
			trace(getTimer());
			var s2:* = SingletonFactory.getInstance();
			trace(s2.toString());
			
			trace(s1==s2);
			
			trace(s1.helloWorld("jimmy"));
			
			
		}
	}
}

但这里有一个不爽的地方,SingleTon2类离开了文件SingletonFactory.as就无法访问了,所以我们在使用时,只能用var s1:* 来声明,虽然可以使用,但是在fd,fb等编程环境中却无法获得代码自动感知!

可以借助接口改进一下:

package
{
	public interface ISingleton
	{
		function toString():String;
		
		function helloWorld(name:String):String;
	}
}

然后让SingleTon2实现该接口

package
{

	public class SingletonFactory
	{
		private static var _instance:Singleton2=null;

		public function SingletonFactory():void
		{
			trace Error("error!");
		}

		public static function getInstance():Singleton2
		{
			if (_instance == null)
			{
				_instance=new Singleton2();
			}
			return _instance;
		}
	}
}

class Singleton2 implements ISingleton //这里改为实现接口
{
	import flash.utils.getTimer;

	private var _createTime:uint;

	public function Singleton2()
	{
		_createTime=getTimer();
	}

	public function toString():String
	{
		return "本实例的创建时间:" + _createTime.toString();
	}

	public function helloWorld(name:String):String
	{
		return "hello " + name + " !";
	}
}

重新测试:

package
{
	import flash.display.Sprite;

	public class main extends Sprite
	{
		public function main()
		{
			var s:ISingleton=SingletonFactory.getInstance();
			trace(s.helloWorld("jimmy.yang"));
		}
	}
}

当然明白了上面的原理后,其实可以更一步简化,既然不声明package的类,只能限制在同一个文件内部的其它类可以访问,何不把它做为构造函数的参数?(这样不就限制了从外部调用构造函数么)

package
{
	public class Singleton2
	{
		private static var _instance:Singleton2;
		
		public function Singleton2(n:_nothing)
		{
				
		}
		
		public static function getInstance():Singleton2{
			if (_instance==null){
				_instance = new Singleton2(new _nothing());				
			}	
			return _instance;
		}
	}
}

class  _nothing{}

这样就清爽多了,当然Singleton模式在AS3中的实现方法不止一种,下面这种也许更容易理解:

package{
	
	public class Singleton{
		
		private static var _instance:Singleton = null;
		
		public function Singleton(){
			if(_instance == null){
				_instance = this;
			}else{
				throw Error("已经存在该类的实例!");
			}
		}
		
		public static function getInstance():Singleton{
			if(_instance != null){
				return _instance;
			}
			return new Singleton();
		}		
		
	}
}

版权声明:本文内容由阿里云实名注册用户自发贡献,版权归原作者所有,阿里云开发者社区不拥有其著作权,亦不承担相应法律责任。具体规则请查看《阿里云开发者社区用户服务协议》和《阿里云开发者社区知识产权保护指引》。如果您发现本社区中有涉嫌抄袭的内容,填写侵权投诉表单进行举报,一经查实,本社区将立刻删除涉嫌侵权内容。

相关文章
阿里云服务器如何登录?阿里云服务器的三种登录方法
购买阿里云ECS云服务器后如何登录?场景不同,大概有三种登录方式:
8996 0
阿里云ECS云服务器初始化设置教程方法
阿里云ECS云服务器初始化是指将云服务器系统恢复到最初状态的过程,阿里云的服务器初始化是通过更换系统盘来实现的,是免费的,阿里云百科网分享服务器初始化教程: 服务器初始化教程方法 本文的服务器初始化是指将ECS云服务器系统恢复到最初状态,服务器中的数据也会被清空,所以初始化之前一定要先备份好。
14634 0
如何设置阿里云服务器安全组?阿里云安全组规则详细解说
阿里云安全组设置详细图文教程(收藏起来) 阿里云服务器安全组设置规则分享,阿里云服务器安全组如何放行端口设置教程。阿里云会要求客户设置安全组,如果不设置,阿里云会指定默认的安全组。那么,这个安全组是什么呢?顾名思义,就是为了服务器安全设置的。安全组其实就是一个虚拟的防火墙,可以让用户从端口、IP的维度来筛选对应服务器的访问者,从而形成一个云上的安全域。
16989 0
阿里云服务器如何登录?阿里云服务器的三种登录方法
购买阿里云ECS云服务器后如何登录?场景不同,云吞铺子总结大概有三种登录方式: 登录到ECS云服务器控制台 在ECS云服务器控制台用户可以更改密码、更换系统盘、创建快照、配置安全组等操作如何登录ECS云服务器控制台? 1、先登录到阿里云ECS服务器控制台 2、点击顶部的“控制台” 3、通过左侧栏,切换到“云服务器ECS”即可,如下图所示 通过ECS控制台的远程连接来登录到云服务器 阿里云ECS云服务器自带远程连接功能,使用该功能可以登录到云服务器,简单且方便,如下图:点击“远程连接”,第一次连接会自动生成6位数字密码,输入密码即可登录到云服务器上。
32687 0
阿里云服务器ECS登录用户名是什么?系统不同默认账号也不同
阿里云服务器Windows系统默认用户名administrator,Linux镜像服务器用户名root
13782 0
阿里云服务器安全组设置内网互通的方法
虽然0.0.0.0/0使用非常方便,但是发现很多同学使用它来做内网互通,这是有安全风险的,实例有可能会在经典网络被内网IP访问到。下面介绍一下四种安全的内网互联设置方法。 购买前请先:领取阿里云幸运券,有很多优惠,可到下文中领取。
18566 0
腾讯云服务器 设置ngxin + fastdfs +tomcat 开机自启动
在tomcat中新建一个可以启动的 .sh 脚本文件 /usr/local/tomcat7/bin/ export JAVA_HOME=/usr/local/java/jdk7 export PATH=$JAVA_HOME/bin/:$PATH export CLASSPATH=.
13388 0
+关注
杨俊明
菩提树下的杨过 http://yjmyzz.cnblogs.com/
1105
文章
0
问答
文章排行榜
最热
最新
相关电子书
更多
OceanBase 入门到实战教程
立即下载
阿里云图数据库GDB,加速开启“图智”未来.ppt
立即下载
实时数仓Hologres技术实战一本通2.0版(下)
立即下载