Unity中的透明效果之开启深度写入半透明效果

在 Unity 中实现开启深度写入的半透明效果是一种特殊的渲染需求
下面详细介绍其原理及相关实现要点。
在常规的半透明渲染中，为了实现正确的混合效果，通常会关闭深度写入（ZWrite Off）。这是因为半透明物体需要按照从后往前的顺序进行渲染，以确保前面的半透明物体能够正确地与后面的物体进行颜色混合。如果开启深度写入，半透明物体在渲染时会将自身的深度值写入深度缓冲区，后续的物体在进行深度测试时，可能会因为前面半透明物体的深度值而被裁剪掉，从而导致渲染结果错误。
开启深度写入的半透明效果原理

1. 分离渲染过程
   开启深度写入的半透明效果的核心思想是将渲染过程分离为两个阶段：深度写入阶段和颜色混合阶段。
   深度写入阶段：在这个阶段，只进行深度写入操作，不进行颜色渲染。通过一个特殊的渲染通道，将半透明物体的深度信息写入深度缓冲区，就好像这些物体是不透明的一样。这样，后续的物体在进行深度测试时，会考虑到半透明物体的深度，避免被错误裁剪。
   颜色混合阶段：在深度写入完成后，再进行正常的半透明颜色混合渲染。此时，深度缓冲区已经包含了半透明物体的深度信息，后续的物体可以根据这个深度信息进行正确的渲染，同时半透明物体也能与其他物体进行正确的颜色混合。

下面是shader代码，创建材质球，选择写的shader，即可实现半透明效果

代码如下：

Shader "Custom/Shadder" {
Properties{
    _Color("Color", Color) = (1,1,1,1)
    _MainTex("MainTex", 2D) = "white" {}
_AlphaScale("Alpha Scale", Range(0, 1)) = 1
}
SubShader{
    Tags{ "Queue" = "Transparent" "IngnoreProjector" = "True" "RenderType" = "Transparent" }
    LOD 200

    Pass{
        ZWrite On
        ColorMask 0
    }

    Pass{
        Tags{ "LightMode" = "ForwardBase" }

        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        CGPROGRAM

        #pragma vertex vert
        #pragma fragment frag

        #include "Lighting.cginc"

        fixed4 _Color;
        sampler2D _MainTex;
        float4 _MainTex_ST;
        fixed _AlphaScale;

        struct a2v {
            float4 vertex : POSITION;
            float4 normal : NORMAL;
            float4 texcoord : TEXCOORD0;
        };

        struct v2f {
            float4 position : SV_POSITION;
            float3 worldNormal : TEXCOORD0;
            float3 worldPos : TEXCOORD1;
            float2 uv : TEXCOORD2;
        };

        v2f vert(a2v v)
        {
            v2f f;
            f.position = UnityObjectToClipPos(v.vertex);

            //计算世界空间下的法线
            f.worldNormal = UnityObjectToWorldNormal(v.normal);

            //计算世界空间下的顶点
            f.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

            //计算变换后的纹理坐标
            f.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

            return f;
        }

        fixed4 frag(v2f i) : SV_Target
        {
            //归一
            fixed3 worldNormal = normalize(i.worldNormal);
            fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

            //纹理颜色
            fixed4 textColor = tex2D(_MainTex, i.uv);


            //反射颜色
            fixed3 albedo = textColor.rgb * _Color.rgb;

            //环境光
            fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

            //漫反射
            fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

            return fixed4(ambient + diffuse, textColor.a * _AlphaScale);
        }

        ENDCG
    }
}
FallBack "Diffuse" 

}

最后自行测试即可