C语言的机器表示

int add(int a,int b)
{
 return a+b;
}

int ref(void)
{

 int t1 = 12;
 int t2 = 34;

 return add(t1,t2);
}

add:
 add.w $a0, $a0, $a1 //a+b
 jr $ra //return
ref:
 addi.d $sp, $sp, -16 //stack allocate
 addi.w $a1, $r0, 34 //t2=34
 addi.w $a0, $r0, 12 //t1=12
 st.d $ra, $sp, 8 //save $ra
 bl add //call add()
 ld.d $ra, $sp, 8 //restore $ra
 addi.d $sp, $sp, 16 //stack release
 jr $ra //return

控制流语句

选择语句

if ~ else

switch ~ case

循环语句

for

while

do ~ while

辅助控制语句

break

continue

goto

return

if (cond_exp)
 then_statement
else
 else_statement

 move $t0, cond_exp
 beqz $t0, .L1
 <then_statement>
 b  .L2
.L1:
 <else_statement>
.L2:

int st(int a, int b, int c)
{
 switch (a) {
  case 15:
   c = b & 0xf;
  case 10:
   return c + 50;
  case 12:
  case 17:
   return b + 50;
  case 14:
   return b;
  default:
   return a;
 }
}

st:
 addi.w $t0,$a0, -10 //a-10
 sltui $t1,$t0, 8
 beqz $t1, default //if (a-10)>=8
       //goto default
 la  $t2, jr_table
 alsl.d $t1, $t0, $t2, 3
       //(a-10)*8+jr_table
 ld.d $t0, $t1, 0
 jr  $t0
default:
 or  $a1,$a0,$r0
case_14:
 or  $a0,$a1,$r0
 jr  $ra  //return b for case_14,
     //return a for default
case_15:
 andi $a2,$a1,0xf  //b & 0xf
case_10:
 addi.w $a1,$a2,50  //c+50
 b  case_14
case_12_17:
 addi.w $a1,$a1,50  //b+50
 b  case_14
       # jump table
 .section .rodata
 .align 3
jr_table:
 .dword case_10
 .dword default
 .dword case_12_17
 .dword default
 .dword case_14
 .dword case_15
 .dword default
 .dword case_12_17

int st(int a, int b, int c)
{
 switch (a) {
  case 15:
   c = b & 0xf;
  case 10:
   return c + 50;
  case 12:
  case 17:
   return b + 50;
  case 14:
   return b;
  default:
   return a;
 }
}

st:
 addi.w $t0,$r0,14
 beq  $a0,$t0,.L7  //(a==14)?
 blt  $t0,$a0,.L3  //(a>14)?
 addi.w $t0,$r0,10
 beq  $a0,$t0,.L4  //(a==10)?
 addi.w $t0,$r0,12
 beq  $a0,$t0,.L5  //(a==12)?
 jr  $ra    //return a
.L3:
 addi.w $t0,$r0,15
 beq  $a0,$t0,.L6  //(a==15)?
 addi.w $t0,$r0,17
 beq  $a0,$t0,.L5  //(a==17)?
 jr  $ra    //return a
.L6:
 andi $a2,$a1,0xf  //b & 0xf
.L4:
 addi.w $a0,$a2,50  //c + 50
 jr  $ra
.L5:
 addi.w $a0,$a1,50  //b + 50
 jr  $ra
.L7:
 or  $a0,$a1,$r0  //return b
 jr  $ra

int test_for(int a) {
 int sum = 0;
 int i = 0;

 for (i = 0; i < a; i++) {
  sum += i;
 }

 return sum;
}


int test_while(int a) {
 int sum = 0;
 int i = 0;

 while (i < a) {
  sum += i;
  i++;
 }

 return sum;
}


int test_dowhile(int a) {
 int sum = 0;
 int i = 0;

 do {
  sum += i;
  i++;
 } while (i < a);

 return sum;
}

test_for:
 or  $t0,$r0,$r0
 or  $t1,$r0,$r0
.L2:
 blt  $t0,$a0,.L3
 or  $a0,$t1,$r0
 jr  $ra
.L3:
 add.w $t1,$t1,$t0
 addi.w $t0,$t0,1
 b  .L2


test_while:
 or  $t0,$r0,$r0
 or  $t1,$r0,$r0
.L2:
 blt  $t0,$a0,.L3
 or  $a0,$t1,$r0
 jr  $ra
.L3:
 add.w $t1,$t1,$t0
 addi.w $t0,$t0,1
 b  .L2

test_dowhile:
 // a : $a0
 // sum : $t0
 // i : $t1
 or $t0,$r0,$r0
 or $t1,$r0,$r0
.L1:
 add.w $t0,$t0,$t1
 addi.w $t1,$t1,1
 blt $t1,$a0,.L1
 or $a0,$t1,$r0
 jr $ra