云虚拟主机asp屏蔽ip访问案例-问答-阿里云开发者社区-阿里云

开发者社区> 问答> 正文

云虚拟主机asp屏蔽ip访问案例

游客nm6mpjb2722bc 2015-08-04 04:30:03 8427
<%
Const BadIPGroup = "42.120.74.100"
If IsForbidIP(BadIPGroup) = True Then
    Response.Write(GetUserIP &"IP地址禁止访问")
    Response.End()
End If

'****************************************************************
'参数vBadIP:要屏蔽的IP段,IP地址集合,用|符号分隔多个IP地址(段)
'返回Bool:True用户IP在被屏蔽范围,False 反之
'****************************************************************
Function IsForbidIP(vBadIP)
  Dim counter, arrIPPart, arrBadIP, arrBadIPPart, i, j

  arrBadIP = Split(vBadIP, "|")
  arrIPPart = Split(GetUserIP(), ".")

  For i = 0 To UBound(arrBadIP)
    counter = 0
    arrBadIPPart = Split(arrBadIP(i), ".")
    For j = 0 To UBound(arrIPPart)
      If (arrBadIPPart(j)) = "*" or Cstr(arrIPPart(j)) = Cstr(arrBadIPPart(j)) Then
         counter = counter + 1
      End If
    Next
    If counter = 4 Then
      IsForbidIP = True
      Exit Function
    End If
  Next
  IsForbidIP = False
End Function

'***************
'返回客户IP地址
'***************
Function GetUserIP()
  Dim IP
  IP = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
  If IP = "" Then IP = Request.ServerVariables("REMOTE_ADDR")
  GetUserIP = IP
End Function
%>

<%
Response.Write("hello,world")
%>

这里以屏蔽本地客户端ip为实例
1、获取本地的ip地址ip.cn/www.ip138.com都可以拿到本地的公网ip地址
屏蔽ip地址的代码:可以用"|"表示或
Const BadIPGroup = "42.120.74.100"
屏蔽前


屏蔽后







开发框架 .NET
分享到
取消 提交回答
全部回答(0)
开发与运维
使用钉钉扫一扫加入圈子
+ 订阅

集结各类场景实战经验,助你开发运维畅行无忧

推荐文章
相似问题
推荐课程