一、前言
这篇文章是 <Linux开发: 学习linux三剑客(awk、sed、grep)(上)>的续集。
二、awk命令
2.1 awk命令基本使用介绍
awk是它的三个作者姓氏的首字母合写，他们是：Aho(阿尔佛雷德·艾侯)、Winberger(彼得·温伯格)和Kernighan(布莱恩·柯林汉)，他们三人合著《AWK程式设计》。
awk是一种文本处理工具，同时它也是一门微型编程语言，它的目的是编写小巧 但充满表达力的程序，把文本的输入变换为文本的输出。用于在linux/unix下对文本和数据进行处理。数据可以来自标准输入(stdin)、一个或多个文件，或其它命令的输出。它支持用户自定义函数和动态正则表达式等先进功能，是linux/unix下的一个强大编程工具。它在命令行中使用，但更多是作为脚本来使用。awk有很多内建的功能，比如数组、函数等，这是它和C语言的相同之处，灵活性是awk最大的优势。
现今的Linux发行版所附带的awk实际上很新，是GNU的重写版本，也叫GNU awk，程序名是gawk。
awk命令格式和选项、语法形式:
awk [options] 'script' var=value file(s) awk [options] -f scriptfile var=value file(s)
常用选项：
-F fs fs指定输入分隔符，fs可以是字符串或正则表达式，如-F: -v var=value 赋值一个用户定义变量，将外部变量传递给awk -f scripfile 从脚本文件中读取awk命令 -m[fr] val 对val值设置内在限制，-mf选项限制分配给val的最大块数目；-mr选项限制记录的最大数目。这两个功能是Bell实验室版awk的扩展功能，在标准awk中不适用
awk的核心思想是模式和行为操作，也叫模式驱动编程。模式一般是关系或正则表达式，用于与输入的每条记录进行匹配；而行为操作则是对模式匹配到的记录的处理方法，采用与C类似的语法，并由一对大括号“｛｝”括起来。
模式
/正则表达式/：使用通配符的扩展集。 关系表达式：使用运算符进行操作，可以是字符串或数字的比较测试。 模式匹配表达式：用运算符~（匹配）和~!（不匹配）。 BEGIN语句块、pattern语句块、END语句块
行为操作
操作由一个或多个命令、函数、表达式组成，之间由换行符或分号隔开，并位于大括号内，主要部分是： 变量或数组赋值 输出命令 内置函数 控制流语句
awk脚本基本结构
awk 'BEGIN{ commands } pattern{ commands } END{ commands }' file
一个awk脚本通常由：BEGIN语句块、能够使用模式匹配的通用语句块、END语句块3部分组成，这三个部分是可选的。任意一个部分都可以不出现在脚本中，脚本通常是被单引号或双引号中。
示例：
例如： awk 'BEGIN{ i=0 } { i++ } END{ print i }' filename awk "BEGIN{ i=0 } { i++ } END{ print i }" filename
awk的工作原理
第一步：执行BEGIN{ commands }语句块中的语句；
第二步：从文件或标准输入(stdin)读取一行，然后执行pattern{ commands }语句块，它逐行扫描文件，从第一行到最后一行重复这个过程，直到文件全部被读取完毕。
第三步：当读至输入流末尾时，执行END{ commands }语句块。
BEGIN语句块在awk开始从输入流中读取行之前被执行，这是一个可选的语句块，比如变量初始化、打印输出表格的表头等语句通常可以写在BEGIN语句块中。
END语句块在awk从输入流中读取完所有的行之后即被执行，比如打印所有行的分析结果这类信息汇总都是在END语句块中完成，它也是一个可选语句块。
pattern语句块中的通用命令是最重要的部分，它也是可选的。如果省略模式，则行为将被应用到每条输入记录；如果省略行为，则默认操作是在标准输出上打印匹配到的记录，执行{ print }。
awk程序的pattern语句块有以下三种情况：
awk 'pattern {commands }' #如果模式匹配，则执行行为 awk 'pattern ' #如果模式匹配，则在标准输出上打印记录执行{ print } awk ' {commands }' # 针对每条记录，执行行为。
示例：
$ echo -e "hello \n my baymax " | awk 'BEGIN{ print "Start" } { print } END{ print "End" }' #完整的结构 #-e参数表示echo内可使用转义字符 $ echo -e "hello \n my baymax " | awk 'BEGIN{ print "Start" } { print } ' #省略end结构 $ echo -e "hello \n my baymax " | awk ' { print } ' #省略前后结构 $ echo -e "hello \n my baymax " | awk ' { print } END{ print "End" }' #省略begin结构
当使用不带参数的print时，它就打印当前行，当print的参数是以逗号进行分隔时，打印时则以空格作为定界符。例如：
$echo | awk '{ var1="v1"; var2="v2"; var3="v3"; print var1,var2,var3; }' v1 v2 v3
在awk的print语句块中双引号是被当作拼接符使用：
echo | awk '{ var1="v1"; var2="v2"; var3="v3"; print var1"="var2"="var3; }'
v1=v2=v3
{ }类似一个循环体，会对文件中的每一行进行迭代，通常变量初始化语句（如：i=0）以及打印文件头部的语句放入BEGIN语句块中，将打印的结果等语句放在END语句块中。
awk内置变量（预定义变量）
说明：[A][N][P][G]表示第一个支持变量的工具，[A]=awk、[N]=nawk、[P]=POSIXawk、[G]=gawk
$n 当前记录的第n个字段，比如n为1表示第一个字段，n为2表示第二个字段。 字段是用空格隔开的单词段。 $0 这个变量包含执行过程中当前行的文本内容。 [A] NF 表示字段数，在执行过程中对应于当前的字段数。而$NF则表示一行中的最后一个字段。$(NF-n)则表示一行中的倒数第n个字段，n为正整数。 [A] NR 表示记录数，在执行过程中对应于当前的行号。 [A] OFMT 数字的输出格式（默认值是%.6g）。 [A] OFS 输出字段分隔符（默认值是一个空格）。 [A] ORS 输出记录分隔符（默认值是一个换行符）。 [A] RS 记录分隔符（默认是一个换行符）。 [A] FILENAME 当前输入文件的名。 [A] FS 字段分隔符（默认是任何空格）。 [G] ARGIND 命令行中当前文件的位置（从0开始算）。 [G] CONVFMT 数字转换格式（默认值为%.6g）。 [G] FIELDWIDTHS 字段宽度列表（用空格键分隔）。 [G] IGNORECASE 如果为真，则进行忽略大小写的匹配。 [N] RSTART 由match函数所匹配的字符串的第一个位置。 [N] RLENGTH 由match函数所匹配的字符串的长度。 [N] SUBSEP 数组下标分隔符（默认值是34）。 [N] ARGV 包含命令行参数的数组。 [N] ARGC 命令行参数的数目。 [N] ERRNO 最后一个系统错误的描述。 [P] ENVIRON 环境变量关联数组。 [P] FNR 同NR，但相对于当前文件。
示例：
需用到内置变量：NR 表示记录数，在执行过程中对应于当前的行号。
需用到内置变量：NF 表示字段数，在执行过程中对应于当前的字段数。而$NF则表示一行中的最后一个字段。
需用到内置变量：$n 当前记录的第n个字段，比如n为1表示第一个字段，n为2表示第二个字段。
$ echo -e "line1 f2 f3\n line2 f4 f5" | awk '{print "Line No:"NR", No of fields:"NF, "$0="$0, "$1="$1, "$2="$2, "$3="$3}'
将外部变量值传递给awk
需用到-v选项，可以将外部值（并非来自stdin）传递给awk，有三种方式。
第一种：写在脚本内（脚本后缀名随意，编辑好直接运行即可）
var1="aaa" var2="bbb" echo | awk '{ print v1,v2 }' v1=$var1 v2=$var2
第二种：传递外部变量方法：
Va=100 echo | awk -v VARIABLE=$Va '{ print VARIABLE }'
第三种：当输入来自于文件时使用??
awk '{ print v1,v2 }' v1=$var1 v2=$var2 filename
以上方法中，变量之间用空格分隔作为awk的命令行参数跟随在BEGIN、{}和END语句块之后。
2.2 awk运算符
awk支持多种运算，这些运算与C语言提供的基本相同。awk还提供了一系列内置的运算函数（如log、sqr、cos、sin等）和一些用于对字符串进行操作（运算）的函数（如length、substr等等）。这些函数的引用大大的提高了awk的运算功能。作为对条件转移指令的一部分，关系判断是每种程序设计语言都具备的功能，awk也不例外，awk中允许进行多种测试，作为样式匹配，还提供了模式匹配表达式~（匹配）和~!（不匹配）。作为对测试的一种扩充，awk也支持用逻辑运算符。
2.2.1 算术运算符
注意：所有用作算术运算符进行操作，操作数自动转为数值，所有非数值都变为0
$ awk 'BEGIN{a="b"; print a++,++a}' #注意这里a="b"后面一定要加;，表明这是一条语句。
2.2.2 赋值运算符
2.2.3 关系运算符
注意：> < 可以作为字符串比较，也可以用作数值比较，关键看操作数如果是字符串就会转换为字符串比较。两个都为数字才转为数值比较。字符串比较：按照ASCII码顺序比较。
2.2.4 逻辑运算符
示例：
$ awk 'BEGIN{a=1;b=2;print (a>5 && b<=2),(a>5 || b<=2);}' 0 1
2.2.5 正则运算符
示例：
需用到正则表达式/^.../,表示以什么内容开头的
$ awk 'BEGIN{a="100testa";if(a ~ /^100*/) {print "ok";}}' ok $ awk 'BEGIN{a="100testa";if(a !~ /^100*/){print "ok";}else {print "error"}}' error
2.2.6 其他运算符
示例：
$ awk 'BEGIN{a="b";arr[0]="b";arr[1]="c";print (b in arr);}' #b in arr问arr是否有b这个下标0 $ awk 'BEGIN{b=0;arr[0]="b";arr[1]="c";print (b in arr);}' #b最初赋值为1，而数组arr下标为1是存在的1
2.2.7 运算符优先级表
2.3 制语句
在linux awk的while、do-while和for语句中允许使用break,continue语句来控制流程走向，也允许使用exit这样的语句来退出。break中断当前正在执行的循环并跳到循环外执行下一条语句。if 是流程选择用法。每条命令语句后面可以用;分号结尾。
2.3.1 if条件判断语句
语法：表达式为真执行语句1，为假执行语句2
if(表达式) 语句1 else 语句2
格式中语句1可以是多个语句，为了方便判断和阅读，最好将多个语句用{}括起来。awk分枝结构允许嵌套，其格式为：
if(表达式) {语句1} else if(表达式) {语句2} else {语句3}
示例：
编写在脚本内
$ cat ass.sh awk 'BEGIN{ test=100; if(test>90){ print "very good"; } else if(test>60){ print "good"; } else{ print "no pass"; } }' 输出结果：very good
2.3.2 while循环语句
语法：表达式为真，循环执行语句，直到条件为假
while(表达式) {语句}
2.3.3 do...while循环语句
语法：先执行语句再判断条件真假，为真则循环执行，为假停止执行。
do {语句} while(条件)
2.3.4 for循环语句
语法一：执行变量初始化，再判断条件，条件为真，执行语句，再执行表达式，再判断条件，条件为真，再执行语句，如此循环直至条件为假。
for(变量初始化;条件;表达式) {语句}
语法二：每次从数组中取一个值赋给变量，再执行语句，循环直到数组内部的数据取完，变量为空。
for(变量 in 数组) {语句}
示例：
需用内置变量ENVIRON ：当前系统环境变量关联数组
[DSYU@DSYU shell]$ cat ass.sh awk 'BEGIN{ for(k in ENVIRON){ print k"="ENVIRON[k]; } }' #每次从环境变量数组中取一个数据赋值给k，然后再打印出来。
2.3.5 ext语句
next 能够导致读入下一个输入行，并返回到脚本的顶部。这可以避免对当前输入行执行其他的操作过程。
awk中next语句使用：在循环逐行匹配，如果遇到next，就会跳过当前行，直接忽略下面语句。而进行下一行匹配。next语句一般用于多行合并：
示例：
需用到内置变量NR：表示记录数，在执行过程中对应于当前的行号
$ awk 'NR%2==1{next}{print NR,$0;}' 123.txt #表示当行号取余2为1也就是奇数行时跳过当前行
2.3.6 其他语句
break 当 break 语句用于 while 或 for 语句时，导致退出程序循环。
continue 当 continue 语句用于 while 或 for 语句时，使程序循环移动到下一个迭代。
exit 语句使主输入循环退出并将控制转移到END,如果END存在的话。如果没有定义END规则，或在END中应用exit语句，则终止脚本的执行。
2.4 数组的运用
数组是awk的灵魂，处理文本中最不能少的就是它的数组处理。因为数组索引（下标）可以是数字和字符串，在awk中数组叫做关联数组(associative arrays)。awk 中的数组不必提前声明，也不必声明大小。数组元素用0或空字符串来初始化，这根据上下文而定。因为数组是关联数组，默认是无序的。所以通过for…in得到是无序的数组。如果需要得到有序数组，需要通过指定下标获得。
2.4.1 数组的定义
awk的数组不必提前声明，也不必声明大小。
数字做数组索引（下标或键值）。
注意：数组下标是从1开始，与C数组不一样。
Array[1]="sun" Array[2]=1970
字符串做数组索引（下标）：
Array["first"]="year" Array["birth"]="1970"
使用中print Array[1]会打印出sun；使用print Array[2]会打印出1970；使用print["first"]会得到year。
示例：
$ awk 'BEGIN {Array["first"]="year"; Array[2]=1970; {print Array["first"]"="Array[2]}}' year=1970 $ awk 'BEGIN {Array["first"]="year"; Array[2]=1970; { for(item in Array) {print Array[item],item}; }}' year first 1970 2 #注意此处是取的数组的下标值赋给item，而不是数组元素值
2.4.2 数组函数
length函数
使用形式：length(array)
length函数返回array数组长度,array可是数组名也可使字符串。
$ awk 'BEGIN { print length("hello")}' 5
split函数
使用形式：split(src,dst,accrod);
split函数以accrod为依据分割src字符串为数组存储到dst内，也会返回分割得到数组长度。
$ awk 'BEGIN{info="it is a test 56 78";lens=split(info,tA,"is");print lens,tA[1],tA[2],tA[3]}' #此示例以is为依据分隔info，分隔为为两个字符串，所以lens为2。 $ awk 'BEGIN{info="it is a test 56 78";lens=split(info,tA,"");print lens,tA[1],tA[2],tA[3]}' #此示例是把info字符串内的所有字符拆分为独立的单个字符存储到tA数组中。
asort函数
使用形式：asort(array);不能对字符串操作。
对array数组进行排序，返回数组长度（下标的个数而不是字符的个数）。
$ awk 'BEGIN{info[1]="it";info[2]="aa";{print asort(info),info[1],info[2]}}' #此示例对info数组排序，返回数组元素个数。
delete
使用形式：delete array[key]，可以删除对应数组array key的序列值。
if(key in array)通过这种方法判断数组中是否包含key键值。
$ awk 'BEGIN{tB["a"]="a1";tB["b"]="b1";delete tB["b"];for(k in tB){print k,tB[k];}}' a a1
2.4.3 二维、多维数组使用
awk的多维数组在本质上是一维数组，更确切一点，awk在存储上并不支持多维数组。awk提供了逻辑上模拟二维数组的访问方式。例如，array[2,4]=1这样的访问是允许的。
类似一维数组的成员测试，多维数组可以使用if ( (i,j) in array)这样的语法，但是下标必须放置在圆括号中。类似一维数组的循环访问，多维数组使用for ( item in array )这样的语法遍历数组。与一维数组不同的是，多维数组必须使用split()函数来访问单独的下标,awk使用一个特殊的字符串SUBSEP作为分割字段。
示例：
可以通过array[k,k2]引用获得数组内容。
awk 'BEGIN{ for(i=1;i<=9;i++){ for(j=1;j<=9;j++){ tarr[i,j]=i*j; print i,"*",j,"=",tarr[i,j]; } } }'
另一种方式：
awk 'BEGIN{ for(i=1;i<=9;i++){ for(j=1;j<=9;j++){ tarr[i,j]=i*j; } } for(m in tarr){ split(m,tarr2,SUBSEP); print tarr2[1],"*",tarr2[2],"=",tarr[m]; } }' # split(m,tarr2,SUBSEP); 运用了SUBSEP特殊字符串，把二维数组的键值m分割存放在tarr2数组中。
2.5 内置函数
awk内置函数，主要分以下：算数函数、字符串函数、其它一般函数、时间函数。
2.5.2 字符串函数
注：Ere都可以是正则表达式。
请参考常用示例。
这里注意sprintf格式化字符串输出
其中格式化字符串包括两部分内容：一部分是正常字符，这些字符将按原样输出; 另一部分是格式化规定字符，以"%"开始，后跟一个或几个规定字符,用来确定输出内容格式。
示例：
$ awk 'BEGIN{n1=124.113;n2=1.224;n3=1.2345; printf("%.2f,%2u,%2g,%X,%o\n",n1,n2,n3,n1,n1);}' 124.11, 1,1.2345,7C,174
2.6 一般函数
getline函数
awk getline用法：输出重定向需用到getline函数。getline从标准输入、管道或者当前正在处理的文件之外的其他输入文件获得输入。它负责从输入获得下一行的内容，并给NF,NR和FNR等内建变量赋值。
如果得到一条记录，getline函数返回1，如果到达文件的末尾就返回0，如果出现错误，例如打开文件失败，就返回-1。
getline语法：getline var，变量var包含了特定行的内容。
awk getline从整体上来说，用法说明：
当其左右无重定向符|或<时：getline作用于当前文件，读入当前文件的第一行给其后跟的变量var或$0（无变量），应该注意到，由于awk在处理getline之前已经读入了一行，所以getline得到的返回结果是隔行的。
当其左右有重定向符|或<时：getline则作用于定向输入文件，由于该文件是刚打开，并没有被awk读入一行，只是getline读入，那么getline返回的是该文件的第一行，而不是隔行。
示例：
执行linux的date命令，并通过管道输出给getline，然后再把输出赋值给自定义变量out，并打印它：
awk 'BEGIN{ "date" | getline out; print out }' test
执行shell的date命令，并通过管道输出给getline，然后getline从管道中读取并将输入赋值给out，split函数把变量out转化成数组mon，然后打印数组mon的第二个元素：
awk 'BEGIN{ "date" | getline out; split(out,mon); print mon[2] }' test
命令ls的输出传递给geline作为输入，循环使getline从ls的输出中读取一行，并把它打印到屏幕。这里没有输入文件，因为BEGIN块在打开输入文件前执行，所以可以忽略输入文件。
awk 'BEGIN{ while( "ls" | getline) print }'
2.7 文件操作
关闭文件
awk中允许在程序中关闭一个输入或输出文件，方法是使用awk的close。
close("filename")
filename可以是getline打开的文件，也可以是stdin，包含文件名的变量或者getline使用的确切命令。或一个输出文件，可以是stdout，包含文件名的变量或使用管道的确切命令。
输出到一个文件
awk中允许用如下方式将结果输出到一个文件：
echo | awk '{printf("hello word!n") > "datafile"}' 或 echo | awk '{printf("hello word!n") >> "datafile"}'
2.8 时间函数
strftime日期和时间格式说明符
2.9 设置字段定界符
默认的字段定界符是空格，可以使用-F "定界符" 明确指定一个定界符：
awk -F: '{ print $NF }' /etc/passwd 或 awk 'BEGIN{ FS=":" } { print $NF }' /etc/passwd
在BEGIN语句块中则可以用OFS=“定界符”设置输出字段的定界符。
2.10 常用示例
2.10.1 打印每一行内容
需用到内置变量：$0 这个变量包含执行过程中当前行的文本内容。
$ awk '{print $0}' 123.txt $ awk '{print }' 123.txt
2.10.2 打印每一行的前面字段
需用到内置变量：$n 当前记录的第n个字段，比如n为1表示第一个字段，n为2表示第二个字段。
$ awk '{print $1,$2}' 123.txt
2.10.3 打印每一行的最后字段
需用到内置变量：$NF表示一行的最后一个字段，
需用到内置变量：$(NF-n)表示一行中的倒数第几个字段，
$ awk '{print $NF}' 123.txt $ awk '{print $(NF-1)}' 123.txt
2.10.4 打印文本总行数
需用到内置变量： NR 表示记录数，在执行过程中对应于当前的行号。
$ awk END'{print NR}' 123.txt #注意此处要用END语句块，如果用通用，则会打印每一行的行号，而END只会打印最后一次的行号，也就是总的行数
2.10.5 算术运算求冥
需用到算术运算符**与^，都表示求冥
$ awk ' BEGIN{print 3**3}' #只有BEGIN语句块，不用输入文件 $ echo | awk ' END{print 3**3}' #有END语句块，必须有输入文件，这里用echo输入一个空字符串 $ echo | awk '{print 3^3} ' #有通用语句块，必须有输入文件
2.10.6 跳过某行
需运用到next语句，表示跳过当前行
需用到正则表达式/...$/，$表明以某内容结尾的
$ awk '/sh$/{next}{print $0}' 123.txt #直接跳过以sh结尾的行
2.10.7 判断关联数组中是否存在某键值
$ awk 'BEGIN{tB["a"]="a1";tB["b"]="b1";if( "c" in tB){print "ok";}else {print "no"};}' no
2.10.8 循环打印数组元素
$ awk 'BEGIN{tB["a"]="a1";tB["b"]="b1";for(k in tB){print k,tB[k];}}'
2.10.9 替换指定字符串
需用到字符串函数：gsub( Ere, Repl, [ In ] ),替换所有与正则表达式相匹配的具体值
需用到字符串函数：sub( Ere, Repl, [ In ] )，替换第一个与正则表达式相匹配的具体值
需用到正则表达式：[-]，表明匹配范围内的任意字符，[0-9]表明匹配0-9的任意数字
需用到正则表达式：+，表明匹配之前的项一次或多次
注意正则表达式需用//括起来。
$ awk 'BEGIN{info="this is a test2010test!2008";gsub(/[0-9]+/,"!",info);print info}' this is a test!test!! [DSYU@DSYU shell]$ awk 'BEGIN{info="this is a test2010test!2008";sub(/[0-9]+/,"!",info);print info}' this is a test!test!2008
2.10.10 指定字符串查找
需用到字符串函数：index( Str1, Str2 )，在str1中寻找str2，有即返回位置（从1开始），没有返回0.
需用到其他运算符：?: ；a?b:c; a为真则b为整个表达式结果，否则c为整个表达式结果。
$ awk 'BEGIN{info="this is a test2010test!";print index(info,"tast")?"ok":"not found";}' not found $ awk 'BEGIN{info="this is a test2010test!";print index(info,"test")?"ok":"no found";}' ok $ awk 'BEGIN{info="this is a test2010test!";print len=index(info,"test");}'
2.10.11 指定正则表达式匹配查找
需用到字符串函数：match( Str, Ere )；成功返回在str中能匹配ERe正则表达式的位置，没有返回0.
需用到正则表达式：[-]，表明匹配范围内的任意字符，[0-9]表明匹配0-9的任意数字
需用到正则表达式：+，表明匹配之前的项一次或多次
注意正则表达式需用//括起来。
$ $ awk 'BEGIN{info="this is a test2010test!";len=match(info,/[0-9]+/);print len}' 15 $ awk 'BEGIN{info="this is a test2010test!";len=match(info,/[5-9]+/);print len}' 0
2.10.12 截取字符串
需用到字符串函数：substr( String, M, [ N ] )，返回从string指定字符串第M个位置（编号从1开始）截取的N个字符组成的字符串。未指定N，则返回M位置到最末尾。
$ awk 'BEGIN{info="this is a test2010test!";print substr(info,4,10)}' s is a tes [DSYU@DSYU shell]$ awk 'BEGIN{info="this is a test2010test!";print substr(info,4)}' s is a test2010test!
2.10.13 字符串分割
需用到字符串函数：split( String, A, [Ere] )，将 String 参数指定的参数以ERe指定的依据为准分割为数组元素 A[1], A[2], . . ., A[n]，并返回 n 变量的值。
$ awk 'BEGIN{info="this is a test";split(info,tA," ");print length(tA);for(k in tA){print k,tA[k];}}' 4 4 test 1 this 2 is 3 a
2.10.14 打开外部文件
需用到一般函数：Expression | getline [ Variable ]，从来自 Expression 参数指定的命令的输出中通过管道传送的流中读取一个输入记录，并将该记录的值指定给 Variable 参数指定的变量。
需用到一般函数：close( Expression )，用同一个带字符串值的 Expression 参数来关闭由 print 或 printf 语句打开的或调用 getline 函数打开的文件或管道。
$ awk 'BEGIN{while("cat /etc/passwd"|getline){print $0;};close("/etc/passwd");}'
2.10.15 获取输入信息
需用到一般函数：getline [ Variable ] file ，读取file内的一行信息存储到Variable 内。如果未指定file，默认从标准输入文件中读取。
$ awk 'BEGIN{print "Enter your name:";getline name;print name;}' Enter your name: yu #此行是用户输入的 yu $ awk 'BEGIN{print "Enter your name:";getline name;print name;}' 123.txt Enter your name: 8.sh 9.sh 10.bck
2.10.16 创建指定时间
需用到时间函数：mktime( YYYY MM dd HH MM ss[ DST])，生成时间格式，返回从1970年1月1日开始到指定时间的的整秒数需用到时间函数：strftime([format [, timestamp]])，格式化时间输出，将时间戳转为时间字符串具体格式。
$ awk 'BEGIN{tmp=mktime("2006 06 06 6 6 6");print strftime("%c",tmp);}' 2006年06月06日 星期二 06时06分06秒
