windows下如何对mysql进行整裤备份

本文涉及的产品
云数据库 RDS MySQL,集群版 2核4GB 100GB
推荐场景:
搭建个人博客
RDS MySQL Serverless 基础系列,0.5-2RCU 50GB
RDS MySQL Serverless 高可用系列,价值2615元额度,1个月
简介:

通常情况下备份一个数据库,直接单裤备份即可,更完善一点的会要求做到定时单裤备份。然而很多时候又由于裤实例是在太多,这样会导致备份非常耗时,因而有时候需要对整个数据库应用进行备份。那么在windows下如何做到对整个应用做定时备份呢?

1、批处理备份脚本(注意修改脚本里面的变量

复制代码
@echo off & setlocal ENABLEEXTENSIONS 
::日期
set TODAY=%date:~0,4%%date:~5,2%%date:~8,2%
::源程序所在目录
set DATAPATH=E:\bak\data\*
::备份目录
set BAKPATH=E:\webInfobackup\
::备份名称前缀
set BAKNAME=mg3MyData

::+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
::+++++++++此目录为备份目录,压缩后会删除,修改时务必注意++++++++
set SRCPATH=%BAKPATH%\%BAKNAME%%TODAY%
::+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

call :Date2Day %date:~0,10% sdays
set /a sdays-=7
call :Day2Date %sdays% difdate

echo start bauckup mysql %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%:%time:~6,2% >>log.log
::关闭mysql服务
net stop mysql
::复制data目录
xcopy %DATAPATH% %SRCPATH%\ /e /y
::开启mysql服务
net start mysql
echo bauckup mysql finish %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%:%time:~6,2% >>log.log

::压缩数据库文件并删除
"C:\Program Files\WinRAR\WinRAR.exe" a -r -ep2 -ibck -inul -df -t %SRCPATH%.rar %SRCPATH%\
echo compress mysql data finish %date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%:%time:~3,2%:%time:~6,2% >>log.log

::++++++++++++++++++删除目录++++++++++++++
rd /q /s %SRCPATH% 
::++++++++++++++++++删除目录++++++++++++++

::删除N天前备份文件
for /r %BAKPATH% %%f in (%BAKNAME%*.rar) do if "%%~tf" LEQ "%difdate%" del "%%f"
goto:EOF exit


:Date2Day
setlocal ENABLEEXTENSIONS 
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do ( 
  set yy=%%a & set mm=%%b & set dd=%%c 
)
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2 
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF 

:Day2Date
setlocal ENABLEEXTENSIONS 
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a 
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5 
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10 
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%) 
endlocal&set %2=%yy%%mm%%dd%&goto :EOF 
复制代码

2、创建任务计划

 不懂的可以GG一下,在此不详细介绍。






本文转自秋楓博客园博客,原文链接:http://www.cnblogs.com/rwxwsblog/p/4525085.html,如需转载请自行联系原作者
相关实践学习
基于CentOS快速搭建LAMP环境
本教程介绍如何搭建LAMP环境,其中LAMP分别代表Linux、Apache、MySQL和PHP。
全面了解阿里云能为你做什么
阿里云在全球各地部署高效节能的绿色数据中心,利用清洁计算为万物互联的新世界提供源源不断的能源动力,目前开服的区域包括中国(华北、华东、华南、香港)、新加坡、美国(美东、美西)、欧洲、中东、澳大利亚、日本。目前阿里云的产品涵盖弹性计算、数据库、存储与CDN、分析与搜索、云通信、网络、管理与监控、应用服务、互联网中间件、移动服务、视频服务等。通过本课程,来了解阿里云能够为你的业务带来哪些帮助     相关的阿里云产品:云服务器ECS 云服务器 ECS(Elastic Compute Service)是一种弹性可伸缩的计算服务,助您降低 IT 成本,提升运维效率,使您更专注于核心业务创新。产品详情: https://www.aliyun.com/product/ecs
目录
相关文章
|
16天前
|
关系型数据库 MySQL 数据安全/隐私保护
windows mysql8 安装后 提示密码不对,修改下密码认证方式就可以了
windows mysql8 安装后 提示密码不对,修改下密码认证方式就可以了
33 3
|
23天前
|
存储 SQL 关系型数据库
|
1月前
|
SQL 关系型数据库 MySQL
Windows 10安装MySQL 5.7完整教程
Windows 10安装MySQL 5.7完整教程
106 2
|
16天前
|
SQL 关系型数据库 MySQL
Navicate,数据库,Mysql,改表,4月29日Finished - Unsuccessfully,导出数据不妨,右键,备份一下Mysql数据库的内容,你想导入和导出数据不如,用查询的方式去做
Navicate,数据库,Mysql,改表,4月29日Finished - Unsuccessfully,导出数据不妨,右键,备份一下Mysql数据库的内容,你想导入和导出数据不如,用查询的方式去做
|
1月前
|
关系型数据库 MySQL 数据安全/隐私保护
windows系统bat批处理 mysql 脚本启动关闭
windows系统bat批处理 mysql 脚本启动关闭
82 3
|
25天前
|
关系型数据库 MySQL 程序员
Windows版本 - MySQL卸载
Windows版本 - MySQL卸载
22 0
|
25天前
|
SQL 关系型数据库 MySQL
MySQL进阶 - 备份与恢复
MySQL进阶 - 备份与恢复
16 0
|
1月前
|
关系型数据库 MySQL 数据库
【条理清晰】在 Windows 上安装 MySQL
【条理清晰】在 Windows 上安装 MySQL
48 0
|
2月前
|
Prometheus Cloud Native 关系型数据库
实时计算 Flink版产品使用合集之binlog被清理掉的问题,并且binlog有备份,有什么方法来恢复到RDS
实时计算Flink版作为一种强大的流处理和批处理统一的计算框架,广泛应用于各种需要实时数据处理和分析的场景。实时计算Flink版通常结合SQL接口、DataStream API、以及与上下游数据源和存储系统的丰富连接器,提供了一套全面的解决方案,以应对各种实时计算需求。其低延迟、高吞吐、容错性强的特点,使其成为众多企业和组织实时数据处理首选的技术平台。以下是实时计算Flink版的一些典型使用合集。
|
2月前
|
SQL 关系型数据库 MySQL
mysql日志管理 、备份与恢复
mysql日志管理 、备份与恢复