开发者社区> 夏春涛> 正文
阿里云
为了无法计算的价值
打开APP
阿里云APP内打开

ASP分页技术源码

简介: 分页示例 //点击"[第一页]"时响应: function PageFirst() {    document.MyForm.CurrentPage.selectedIndex=0;   document.
+关注继续查看
<%''本程序文件名为:Pages.asp%>
<%''包含ADO常量表文件adovbs.inc,可从"\Program Files\Common Files\System\ADO"目录下拷贝%>
<!--#Include File="adovbs.inc"-->
<%''*建立数据库连接,这里是Oracle8.05数据库
 Set conn=Server.CreateObject("ADODB.Connection")  
 conn.Open "Provider=msdaora.1;Data Source=YourSrcName;User ID=YourUserID;Password=YourPassword;"  

 Set rs=Server.CreateObject("ADODB.Recordset")   ''创建Recordset对象
 rs.CursorLocation=adUseClient                   ''设定记录集指针属性
 ''*设定一页内的记录总数,可根据需要进行调整
 rs.PageSize=10                                    
 
 ''*设置查询语句    
 StrSQL="Select ID,姓名,住址,电话 from 通讯录 Order By ID"        
 rs.Open StrSQL,conn,adOpenStatic,adLockReadOnly,adCmdText
%>
<HTML>
<HEAD>
<title>分页示例</title>
<script language=javascript>
 //点击"[第一页]"时响应:
 function PageFirst()
 {
   document.MyForm.CurrentPage.selectedIndex=0;
   document.MyForm.CurrentPage.onchange();
 }
 //点击"[上一页]"时响应:
 function PagePrior()
 {    
   document.MyForm.CurrentPage.selectedIndex--;
   document.MyForm.CurrentPage.onchange();
 }
 //点击"[下一页]"时响应:
 function PageNext()
 {
   document.MyForm.CurrentPage.selectedIndex++;
   document.MyForm.CurrentPage.onchange();        
 }
 //点击"[最后一页]"时响应:
 function PageLast()
 {  
   document.MyForm.CurrentPage.selectedIndex=document.MyForm.CurrentPage.length-1;
   document.MyForm.CurrentPage.onchange();
 }
 //选择"第?页"时响应:
 function PageCurrent()
 { //Pages.asp是本程序的文件名
   document.MyForm.action='Pages.asp?Page='+(document.MyForm.CurrentPage.selectedIndex+1)
   document.MyForm.submit();
 }  
</Script>
</HEAD>
<BODY bgcolor="#ffffcc" link="#008000" vlink="#008000" alink="#FF0000"">
 
<%IF rs.Eof THEN
   Response.Write("<font size=2 color=#000080>[数据库中没有记录!]</font>")
 ELSE  
   ''指定当前页码
   If Request("CurrentPage")="" Then
     rs.AbsolutePage=1
   Else
     rs.AbsolutePage=CLng(Request("CurrentPage"))
   End If  
   
   ''创建表单MyForm,方法为Get
   Response.Write("<form method=Get name=MyForm>")  
   Response.Write("<p align=center><font size=2 color=#008000>")
   ''设置翻页超链接
   if rs.PageCount=1 then  
     Response.Write("[第一页] [上一页] [下一页] [最后一页] ")
   else
       if rs.AbsolutePage=1 then
         Response.Write("[第一页] [上一页] ")
         Response.Write("[<a href=javascript:PageNext()>下一页</a>] ")
         Response.Write("[<a href=javascript:PageLast()>最后一页</a>] ")
       else
           if rs.AbsolutePage=rs.PageCount then
             Response.Write("[<a href=javascript:PageFirst()>第一页</a>] ")
             Response.Write("[<a href=javascript:PagePrior()>上一页</a>] ")
             Response.Write("[下一页] [最后一页] ")
           else
               Response.Write("[<a href=javascript:PageFirst()>第一页</a>] ")
               Response.Write("[<a href=javascript:PagePrior()>上一页</a>] ")
               Response.Write("[<a href=javascript:PageNext()>下一页</a>] ")
               Response.Write("[<a href=javascript:PageLast()>最后一页</a>] ")
           end if
       end if
   end if
   
   ''创建下拉列表框,用于选择浏览页码
   Response.Write("第<select size=1 name=CurrentPage onchange=PageCurrent()>")    
   For i=1 to rs.PageCount
     if rs.AbsolutePage=i then
        Response.Write("<option selected>"&i&"</option>")  ''当前页码
     else
        Response.Write("<option>"&i&"</option>")
     end if  
   Next
   Response.Write("</select>页/共"&rs.PageCount&"页 共"&rs.RecordCount&"条记录</font><p>")
   Response.Write("</form>")
   
   ''创建表格,用于显示
   Response.Write("<table align=center cellspacing=1 cellpadding=1 border=1")    
   Response.Write(" bordercolor=#99CCFF bordercolordark=#b0e0e6 bordercolorlight=#000066>")
   
   Response.Write("<tr bgcolor=#ccccff bordercolor=#000066>")
     
   Set Columns=rs.Fields
   
   ''显示表头
   For i=0 to Columns.Count-1
     Response.Write("<td align=center width=200 height=13>")
     Response.Write("<font size=2><b>"&Columns(i).name&"</b></font></td>")  
   Next
   Response.Write("</tr>")
   ''显示内容
   For i=1 to rs.PageSize
     Response.Write("<tr bgcolor=#99ccff bordercolor=#000066>")
     For j=0 to Columns.Count-1
       Response.Write("<td><font size=2>"&Columns(j)&"</font></td>")
     Next
     Response.Write("</tr>")
     
     rs.movenext
     if rs.EOF then exit for
   Next
   
   Response.Write("</table>")

 END IF
%>
</BODY>
</HTML>
<%
 ''===程序在Win2000Server+IIS5.0+Oracle8.05下测试通过===
 ''===作者:夏春涛        E-mail:xchuntao@163.com===
%>

版权声明:本文内容由阿里云实名注册用户自发贡献,版权归原作者所有,阿里云开发者社区不拥有其著作权,亦不承担相应法律责任。具体规则请查看《阿里云开发者社区用户服务协议》和《阿里云开发者社区知识产权保护指引》。如果您发现本社区中有涉嫌抄袭的内容,填写侵权投诉表单进行举报,一经查实,本社区将立刻删除涉嫌侵权内容。

相关文章
ASP.NET自定义控件组件开发 第一章 第三篇
原文:ASP.NET自定义控件组件开发 第一章 第三篇                                             第三篇:第一章的完结篇     系列文章链接: ASP.
887 0
ASP.NET自定义控件组件开发 第一章 第二篇 接着待续
原文:ASP.NET自定义控件组件开发 第一章 第二篇 接着待续      ASP.NET自定义控件组件开发 第一章 第二篇 接着待续     很感谢大家给我的第一篇ASP.NET控件开发的支持!在写这些之前,我也看了一些例子,想选中一些好上手的例子,这样,可能一些例子大家以前都见过,但是我想说:同样是弹钢琴,同样一首“命运交响曲”,有的人弹的让人荡气回肠,有的人弹的就很一般。
914 0
.NET/ASP.NET 4.5 Bundle组件(捆绑、缩小静态文件)
阅读目录: 1.开篇介绍 2.System.Web.Optimization 组件 3.System.Web.Optimization 组件基本原理 4.扩展自定义类型静态文件 1】开篇介绍 这篇文章将简单的分析一下有关静态文件捆绑的ASP.
742 0
[转]性能比较:.NET Remoting 与 ASP.NET Web 服务
http://www.cnblogs.com/cheatlove/articles/385119.html 摘要:本文对 Microsoft ASP.NET Web 服务与 Microsoft .NET Remoting 的相对性能进行比较。
1159 0
一起谈.NET技术,asp.net控件开发基础(10)
  集合属性相信大家都很熟悉也很常用,如DropDownList,ListBox等控件             测试1            测试2            测试3           1.实现集合属性效果   经过前面几篇的学习,相信这一篇看起来已经相对简单了.我们要做的就是,先定义一个复杂属性,然后用迭代语句获取数组数据即可。
766 0
+关注
夏春涛
曾任教于信息工程大学16年,长期从事计算机软件与信息安全教学科研工作,目前任职于某软件公司从事技术管理工作,擅长架构设计、开发管理,对大数据、分布式颇感兴趣。
文章
问答
文章排行榜
最热
最新
相关电子书
更多
低代码开发师(初级)实战教程
立即下载
阿里巴巴DevOps 最佳实践手册
立即下载
冬季实战营第三期:MySQL数据库进阶实战
立即下载