AI 助理
备案控制台
开发者社区 开发与运维 文章 正文

MS SQL 监控磁盘空间告警

2013-05-08 828
版权
版权声明：
本文内容由阿里云实名注册用户自发贡献，版权归原作者所有，阿里云开发者社区不拥有其著作权，亦不承担相应法律责任。具体规则请查看《 阿里云开发者社区用户服务协议》和 《阿里云开发者社区知识产权保护指引》。如果您发现本社区中有涉嫌抄袭的内容，填写 侵权投诉表单进行举报，一经查实，本社区将立刻删除涉嫌侵权内容。
简介： 原文 http://www.cnblogs.com/kerrycode/archive/2013/05/07/3065960.html 这几天突然有个想法：希望能够自动监控、收集数据库服务器的磁盘容量信息，当达到一个阀值后，自动发送告警邮件给DBA，将数据库磁盘详细信息告知DBA，提醒DBA做好存储规划计划，初步的想法是通过作业调用存储过程来实现（每天调用一次），这样避免了我每天每台数据库服务器都上去检查一下，尤其是手头的数据库服务器N多的情况，这样可以避免我每天浪费无谓的时间。

原文 http://www.cnblogs.com/kerrycode/archive/2013/05/07/3065960.html

这几天突然有个想法：希望能够自动监控、收集数据库服务器的磁盘容量信息，当达到一个阀值后，自动发送告警邮件给DBA，将数据库磁盘详细信息告知DBA，提醒DBA做好存储规划计划，初步的想法是通过作业调用存储过程来实现（每天调用一次），这样避免了我每天每台数据库服务器都上去检查一下，尤其是手头的数据库服务器N多的情况，这样可以避免我每天浪费无谓的时间。如果大家有更好的建议和方法，欢迎指点一二，我整理、修改了三个存储过程如下：

存储过程1：SP_DiskCapacityAlert1.prc

说 明：需要通过调用OLE 自动存储过程获取磁盘信息，而这些组件，基于服务器的安全配置，通常是禁用的，我们在存储过程通过sp_configure开启这个服务，调用服务完毕 后，又通过sp_configure禁用该服务。另外，数据库服务器都位于内网，因此安全问题应该不大。

USE master;
GO
 
SET ANSI_NULLS ON
GO
 
SET QUOTED_IDENTIFIER ON
GO
 
 
 
IF EXISTS (SELECT 1 FROM dbo.sysobjects WHERE id = OBJECT_ID(N'sp_diskcapacity_alert1') AND OBJECTPROPERTY(id, 'IsProcedure') =1)
    DROP PROCEDURE sp_diskcapacity_alert1;
GO
 
--==================================================================================================================
--        ProcedureName        :            sp_diskcapacity_alert1
--        Author               :            Kerry    
--        CreateDate           :            2013-05-02
--        Description          :            获取数据库所在服务器的磁盘容量，当达到阀值是，发送告警邮件，提醒DBA做好存储规划计划
/******************************************************************************************************************
    Modified Date        Modified User        Version                    Modified Reason
    2013-05-6               Kerry            V01.00.00          修改HTML输出样式.以及磁盘容量输出改为GB
*******************************************************************************************************************/
--==================================================================================================================
CREATE PROCEDURE [dbo].[sp_diskcapacity_alert1]
(
        @Threshold    NUMERIC
)
AS
 
SET NOCOUNT ON
 
 
DECLARE @Result                INT;
DECLARE @objectInfo            INT;
DECLARE @DriveInfo             CHAR(1);
DECLARE @TotalSize             VARCHAR(20);
DECLARE @OutDrive              INT;
DECLARE @UnitMB                BIGINT;
DECLARE @HtmlContent           NVARCHAR(MAX) ; 
DECLARE @FreeRat               NUMERIC;
DECLARE @EmailHead             VARCHAR(120);
SET @UnitMB = 1048576;
 
 
 
 
--创建临时表保存服务器磁盘容量信息
CREATE TABLE #DiskCapacity
(
    [DiskCD]        CHAR(1) ,
    FreeSize        INT        ,
    TotalSize       INT        
);
 
INSERT #DiskCapacity
        ([DiskCD], FreeSize ) 
EXEC master.dbo.xp_fixeddrives;
 
EXEC sp_configure 'show advanced options', 1
RECONFIGURE WITH OVERRIDE;
 
EXEC sp_configure 'Ole Automation Procedures', 1;
RECONFIGURE WITH OVERRIDE;
 
 
EXEC @Result = master.sys.sp_OACreate 'Scripting.FileSystemObject',@objectInfo OUT;
 
DECLARE CR_DiskInfo CURSOR LOCAL FAST_FORWARD
FOR SELECT  DiskCD FROM #DiskCapacity
ORDER by DiskCD
 
OPEN CR_DiskInfo;
 
FETCH NEXT FROM CR_DiskInfo INTO @DriveInfo
 
WHILE @@FETCH_STATUS=0
BEGIN
 
    EXEC @Result = sp_OAMethod @objectInfo,'GetDrive', @OutDrive OUT, @DriveInfo
 
 
    EXEC @Result = sp_OAGetProperty @OutDrive,'TotalSize', @TotalSize OUT
 
 
    UPDATE #DiskCapacity
    SET TotalSize=@TotalSize/@UnitMB
    WHERE DiskCD=@DriveInfo
 
    FETCH NEXT FROM CR_DiskInfo INTO @DriveInfo
 
END
 
CLOSE CR_DiskInfo
DEALLOCATE CR_DiskInfo;
 
EXEC @Result=sp_OADestroy @objectInfo
 
EXEC sp_configure 'show advanced options', 1
RECONFIGURE WITH OVERRIDE;
 
EXEC sp_configure 'Ole Automation Procedures', 0;
RECONFIGURE WITH OVERRIDE;
 
EXEC sp_configure 'show advanced options', 0
RECONFIGURE WITH OVERRIDE;
 
SELECT @FreeRat =FreeRate
FROM (
        SELECT ROW_NUMBER() OVER (ORDER BY FreeSize / ( TotalSize * 1.0 ) ASC) AS RowIndex,
               CAST(( FreeSize / ( TotalSize * 1.0 ) ) * 100.0 AS INT)          AS FreeRate  
             
        FROM    #DiskCapacity
     ) T
WHERE RowIndex = 1;
 
    IF @FreeRat <= @Threshold
        BEGIN
        
        IF @FreeRat > 10 AND @FreeRat <=20 
            SET @EmailHead ='数据库磁盘容量告警(告警级别3)'
        ELSE IF @FreeRat >=5 AND @FreeRat <=10
            SET @EmailHead ='数据库磁盘容量告警(告警级别4)'
        ELSE
            SET @EmailHead ='数据库磁盘容量告警(告警级别5)'
        
        SET @HtmlContent =
            +   N'<html>'
            +   N'<style type="text/css">'
            +   N' td {border:solid #9ec9ec;  border-width:0px 1px 1px 0px; padding:4px 0px;}'
            +   N' table {border:1px solid #9ec9ec; width:100%;border-width:1px 0px 0px 1px;text-align:center;font-size:12px}'
            +   N'</style>'
            +   N'<H1 style="color:#FF0000; text-align:center;font-size:14px">' + @EmailHead +'</H1>'    
            +   N'<table  >'    
            +   N'<tr><th>磁盘盘符</th><th>总大小(GB)</th><th>已用空间(GB)</th><th>剩余空间(GB)</th>'     
            +   N'<th>已用比例(%)</th><th>剩余比例(%)</th></tr >' +    
            CAST ( ( SELECT 
            td =  DiskCD                                                , '',
            td = STR(TotalSize*1.0/1024,6,2)                            , '',  
            td = STR((TotalSize - FreeSize)*1.0/1024,6,2)               , '',                          
            td = STR(FreeSize*1.0/1024,6,2)                             , '',    
            td = STR(( TotalSize - FreeSize)*1.0/(TotalSize)* 100.0,6,2), '',         
            td = STR(( FreeSize * 1.0/ ( TotalSize  ) ) * 100.0,6,2)    , ''              
            FROM #DiskCapacity
            FOR XML PATH('tr'), TYPE     ) AS NVARCHAR(MAX) ) +     N'</table></html>' ; 
            
         
            
         EXEC msdb.dbo.sp_send_dbmail     
            @profile_name = 'DataBase_DDL_Event',    --指定你自己的profile_name    
            @recipients='****@163.com',                --指定你要发送到的邮箱
            @subject = '服务器磁盘空间告警',     
            @body = @HtmlContent,   
            @body_format = 'HTML' ; 
        END
 
    
DROP TABLE #DiskCapacity;
 
RETURN;
 
GO
 
 

存储过程2：SP_DiskCapacityAlert2.prc

说明：需要启用xp_cmdshell来获取磁盘信息，关于xp_cmdshell安全隐患，一般该功能都是禁用的。

USE [master]
GO
 
 
SET ANSI_NULLS ON
GO
 
SET QUOTED_IDENTIFIER ON
GO
 
IF OBJECT_ID(N'dbo.sp_diskcapacity_alert2') IS NOT NULL
    DROP PROCEDURE dbo.sp_diskcapacity_alert2;
 
GO
 
--==================================================================================================================
--        ProcedureName        :            sp_diskcapacity_alert2
--        Author               :            Kerry    
--        CreateDate           :            2013-05-02
--        Description          :            获取数据库所在服务器的磁盘容量，当达到阀值时，发送告警邮件，提醒DBA做好存储规划计划
/******************************************************************************************************************
    Modified Date        Modified User        Version                    Modified Reason
    2013-05-6             Kerry                 V01.00.00                修改HTML输出样式.以及磁盘容量输出改为GB
*******************************************************************************************************************/
--==================================================================================================================
CREATE PROCEDURE [dbo].[sp_diskcapacity_alert2]
(
        @Threshold    NUMERIC
)
    
AS 
BEGIN
    
SET NOCOUNT ON;
 
DECLARE @HtmlContent    NVARCHAR(MAX) ; 
DECLARE @FreeRat        NUMERIC;
DECLARE @EmailHead        VARCHAR(200);
 
--创建临时表保存服务器磁盘容量信息
CREATE TABLE #DiskCapacity
(
    DiskCD            CHAR(4) ,
    FreeSize        　INT        ,
    TotalSize         BIGINT        
);
 
INSERT INTO #DiskCapacity
        ( DiskCD, FreeSize )
EXEC master..xp_fixeddrives;
 
 
 
EXEC sp_configure 'show advanced options', 1
RECONFIGURE
EXEC sp_configure 'xp_cmdshell', 1
RECONFIGURE
EXEC sp_configure 'show advanced options', 0
RECONFIGURE
 
 
CREATE TABLE #DriveInfo1(ID INT IDENTITY(1,1),DiskCD VARCHAR(12));
 
INSERT INTO #DriveInfo1(DiskCD)
EXEC xp_cmdshell 'wmic LOGICALDISK get name';
 
 
CREATE TABLE #DriveInfo2(ID INT IDENTITY(1,1), TotalSize VARCHAR(22));
 
INSERT INTO #DriveInfo2
        ( TotalSize )
EXEC  xp_cmdshell 'wmic LOGICALDISK get size';
 
  
DELETE FROM #DriveInfo1 WHERE ID=1;
DELETE FROM #DriveInfo2 WHERE ID=1;
 
  
UPDATE #DriveInfo1 SET DiskCD = REPLACE(DiskCD,':','');
SELECT * FROM #DiskCapacity
 
UPDATE #DiskCapacity  SET TotalSize =(SELECT CAST(LEFT(N.TotalSize, LEN(N.TotalSize)-1) AS BIGINT)/1024/1024 FROM #DriveInfo1 M INNER JOIN #DriveInfo2 N ON M.ID = N.ID
WHERE M.DiskCD IS NOT NULL AND LEN(M.DiskCD) >1 AND #DiskCapacity.DiskCD = LEFT(M.DiskCD, LEN(M.DiskCD)-1))
  
  SELECT * FROM #DiskCapacity
  
EXEC sp_configure 'show advanced options', 1
RECONFIGURE
EXEC sp_configure 'xp_cmdshell', 0
RECONFIGURE
EXEC sp_configure 'show advanced options', 0
RECONFIGURE
 
SELECT @FreeRat =FreeRate
FROM (
        SELECT ROW_NUMBER() OVER (ORDER BY FreeSize / ( TotalSize * 1.0 ) ASC) AS RowIndex,
               CAST(( FreeSize / ( TotalSize * 1.0 ) ) * 100.0 AS INT)     AS FreeRate  
             
        FROM    #DiskCapacity
     ) T
WHERE RowIndex = 1;
 
    IF @FreeRat <= @Threshold
        BEGIN
        
        IF @FreeRat > 10 AND @FreeRat <=20 
            SET @EmailHead ='数据库磁盘容量告警(告警级别3)'
        ELSE IF @FreeRat >=5 AND @FreeRat <=10
            SET @EmailHead ='数据库磁盘容量告警(告警级别4)'
        ELSE
            SET @EmailHead ='数据库磁盘容量告警(告警级别5)'
        
        SET @HtmlContent =
            +   N'<html>'
            +   N'<style type="text/css">'
            +   N' td {border:solid #9ec9ec;  border-width:0px 1px 1px 0px; padding:4px 0px;}'
            +   N' table {border:1px solid #9ec9ec; width:100%;border-width:1px 0px 0px 1px;text-align:center;font-size:12px}'
            +   N'</style>'
            +   N'<H1 style="color:#FF0000; text-align:center;font-size:14px">' + @EmailHead +'</H1>'    
            +   N'<table  >'    
            +   N'<tr><th>磁盘盘符</th><th>总大小(GB)</th><th>已用空间(GB)</th><th>剩余空间(GB)</th>'     
            +   N'<th>已用比例(%)</th><th>剩余比例(%)</th></tr >' +    
            CAST ( ( SELECT 
            td =  DiskCD                                                , '',
            td = STR(TotalSize*1.0/1024,6,2)                            , '',  
            td = STR((TotalSize - FreeSize)*1.0/1024,6,2)               , '',                          
            td = STR(FreeSize*1.0/1024,6,2)                             , '',    
            td = STR(( TotalSize - FreeSize)*1.0/(TotalSize)* 100.0,6,2), '',         
            td = STR(( FreeSize * 1.0/ ( TotalSize  ) ) * 100.0,6,2)    , ''              
            FROM #DiskCapacity
            FOR XML PATH('tr'), TYPE     ) AS NVARCHAR(MAX) ) +     N'</table></html>' ; 
            
         
            
         EXEC msdb.dbo.sp_send_dbmail     
            @profile_name = 'DataBase_DDL_Event', --指定你自己的profile_name       
            @recipients='konglb@***.com',         --指定你要发送到的邮箱
            @subject = '服务器磁盘空间告警',     
            @body = @HtmlContent,   
            @body_format = 'HTML' ; 
        END
 
END 
 
GO

存储过程3：SP_DiskCapacityAlert2.prc

说明：这个存储过程不用上面两个有安全隐患的存储过程，但是获取不到磁盘的总体信息，就不能通过一个阀值来告警，只能设置当磁盘剩余多少空间时，产生告警邮件。

USE [master]
GO
 
 
SET ANSI_NULLS ON
GO
 
SET QUOTED_IDENTIFIER ON
GO
 
IF OBJECT_ID(N'dbo.sp_diskcapacity_alert3') IS NOT NULL
    DROP PROCEDURE dbo.sp_diskcapacity_alert3;
 
GO
 
--==================================================================================================================
--        ProcedureName        :            sp_diskcapacity_alert3
--        Author               :            Kerry    
--        CreateDate           :            2013-05-02
--        Description          :            获取数据库所在服务器的磁盘容量，当某个磁盘剩余容量低于某个值时，发送告警邮件，
--                                          提醒DBA做好存储规划计划
/******************************************************************************************************************
    Modified Date        Modified User        Version                    Modified Reason
    2013-05-6                Kerry          V01.00.00           修改HTML输出样式.以及磁盘容量输出改为GB
*******************************************************************************************************************/
--==================================================================================================================
CREATE PROCEDURE [dbo].[sp_diskcapacity_alert3]
(
        @DiskCapacity    FLOAT
)
    
AS 
BEGIN
 
DECLARE @FreeSize         INT;
DECLARE @EmailHead        VARCHAR(200);
DECLARE @HtmlContent      NVARCHAR(MAX) ; 
 
 
--创建临时表保存服务器磁盘容量信息
CREATE TABLE #DiskCapacity
(
    DiskCD            CHAR(4) ,
    FreeSize        INT            
);
 
INSERT INTO #DiskCapacity
        ( DiskCD, FreeSize )
EXEC master..xp_fixeddrives;
 
SELECT  @FreeSize = FreeSize*1.0/1024
FROM    ( SELECT    ROW_NUMBER() OVER ( ORDER BY FreeSize ASC ) AS RowIndex ,
                    FreeSize AS FreeSize
          FROM      #DiskCapacity
        ) T
WHERE   RowIndex = 1 ;
 
SELECT FreeSize*1.0/1024 FROM  #DiskCapacity;
  IF @FreeSize <= @DiskCapacity 
    BEGIN
        
        IF @FreeSize > 1
            AND @FreeSize <= 2 
            SET @EmailHead = '数据库磁盘容量告警(告警级别3)'
        ELSE 
            IF @FreeSize >= 0.5
                AND @FreeSize <= 1 
                SET @EmailHead = '数据库磁盘容量告警(告警级别4)'
            ELSE 
                SET @EmailHead = '数据库磁盘容量告警(告警级别5)'
        
        SET @HtmlContent = +N'<html>' + N'<style type="text/css">'
            + N' td {border:solid #9ec9ec;  border-width:0px 1px 1px 0px; padding:4px 0px;}'
            + N' table {border:1px solid #9ec9ec; width:100%;border-width:1px 0px 0px 1px;text-align:center;font-size:12px}'
            + N'</style>'
            + N'<H1 style="color:#FF0000; text-align:center;font-size:14px">'
            + @EmailHead + '</H1>' + N'<table  >'
            + N'<tr><th>磁盘盘符</th><th>剩余空间(GB)</th>' + N'</tr >'
            + CAST(( SELECT td = DiskCD ,
                            '' ,
                            td = STR(FreeSize * 1.0 / 1024, 6, 2) ,
                            ''
                     FROM   #DiskCapacity
                   FOR
                     XML PATH('tr') ,
                         TYPE
                   ) AS NVARCHAR(MAX)) + N'</table></html>' ; 
                   
           EXEC msdb.dbo.sp_send_dbmail     
            @profile_name = 'DataBase_DDL_Event',  --指定你自己的profile_name   
            @recipients='konglb@***.com',          --指定你要发送到的邮箱
              @subject = '服务器磁盘空间告警',     
            @body = @HtmlContent,   
            @body_format = 'HTML' ; 
            
    END
 
END
GO
作者： 潇湘隐者

本文版权归作者和博客园共有，欢迎转载，但未经作者同意必须保留此段声明，且在文章页面明显位置给出原文连接.
文章标签：
数据库
Go
SQL
监控
存储
前端开发
数据库管理
安全
数据格式
XML
关键词：
SQL监控
SQL告警
SQL MS
SQL监控磁盘空间告警
SQL磁盘空间
杰克.陈
目录
相关文章
陌陌谣
|
1月前
|
SQL 数据采集 监控
局域网监控电脑屏幕软件：PL/SQL 实现的数据库关联监控
在当今网络环境中，基于PL/SQL的局域网监控系统对于企业和机构的信息安全至关重要。该系统包括屏幕数据采集、数据处理与分析、数据库关联与存储三个核心模块，能够提供全面而准确的监控信息，帮助管理者有效监督局域网内的电脑使用情况。
陌陌谣
22 2
陌陌谣
|
1月前
|
SQL 监控 安全
员工上网行为监控软件：SQL 在数据查询监控中的应用解析
在数字化办公环境中，员工上网行为监控软件对企业网络安全和管理至关重要。通过 SQL 查询和分析数据库中的数据，企业可以精准了解员工的上网行为，包括基础查询、复杂条件查询、数据统计与分析等，从而提高网络管理和安全防护的效率。
陌陌谣
28 0
游客otvqgjsxhwuvm
|
4月前
|
SQL 监控 Java
SQL质量监控
为帮助用户管理和优化SLS中的SQL查询，提供了用户级SQL质量监控功能，集成于CloudLens for SLS。开启服务后约10分钟，用户可在「报表中心 / SQL质量监控」中查看数据。 该功能包括： SQL健康分和使用报告：反馈总体质量。 服务指标：如请求PV数、平均延时等，用于业务分析。 运行指标：如并发请求、处理数据量等。 SQL Pattern分析：提炼SQL语义特征，识别业务特征。 质量优化建议：基于请求成功率和错误码分布给出改进建议。 监控功能以分钟为单位聚合分析数据，不包括JDBC接入和ScheduledSQL流量，并可能随产品发展而调整。这些功能有助于用户全面掌握SQL
游客otvqgjsxhwuvm
67 15
SQL质量监控
WXM
|
5月前
|
SQL 运维 分布式计算
如何做好SQL质量监控
为满足用户对SQL分析行为的监控和质量管理需求，我们推出了用户级SQL质量监控功能。此功能集成于CloudLens for SLS中，可轻松开启以监控和管理所有SLS相关资源（包括采集接入、读写操作、作业、配额、SQL、计费等）。
WXM
37 2
如何做好SQL质量监控
陌陌谣
|
5月前
|
存储 监控 数据库
局域网监控软件中的Transact-SQL事务管理
**T-SQL事务管理**确保数据的原子性、一致性、隔离性和持久性。使用`BEGIN TRANSACTION`, `COMMIT`和`ROLLBACK`来控制事务。例如，在更新账户余额的事务中，如果所有操作成功则提交，否则回滚。错误处理通过`TRY-CATCH`结构实现，嵌套事务允许在事务内开启新的事务。通过触发器和存储过程，如`DataChangeTrigger`和`SubmitDataToWebsite`，可以自动化数据提交到网站，当表数据变动时触发。
陌陌谣
45 5
今天是几号
|
6月前
|
SQL 监控 安全
代码审计-PHP原生开发篇&SQL注入&数据库监控&正则搜索&文件定位&静态分析
代码审计-PHP原生开发篇&SQL注入&数据库监控&正则搜索&文件定位&静态分析
今天是几号
69 6
1442834948473151
|
6月前
|
SQL 缓存 监控
sql server数据库监控
SQL Server数据库监控是收集、聚合和观察SQL服务器的各项指标的过程，旨在维护SQL数据库的运行状况和可用性。由于SQL数据库服务器的问题经常被识别为导致延迟等问题的原因，因此，对其进行监控显
1442834948473151
50 0
开发者小达人
|
SQL 存储 监控
FAQ系列 | 监控平均SQL响应时长
FAQ系列 | 监控平均SQL响应时长
开发者小达人
230 0
游客j4mujezz7vm7y
|
3月前
|
关系型数据库 MySQL 网络安全
5-10Can't connect to MySQL server on 'sh-cynosl-grp-fcs50xoa.sql.tencentcdb.com' (110)")
5-10Can't connect to MySQL server on 'sh-cynosl-grp-fcs50xoa.sql.tencentcdb.com' (110)")
游客j4mujezz7vm7y
38 0
sunrr
|
5月前
|
SQL 存储 监控
SQL Server的并行实施如何优化？
【7月更文挑战第23天】SQL Server的并行实施如何优化？
sunrr
129 13

热门文章

最新文章

  • 1
    PostgreSQL SQL HINT的使用
  • 2
    SQL0286N. DB2表空间的pagesize问题
  • 3
    SQL语句如何强制使用索引
  • 4
    SQL Server 统计信息更新时采样百分比对数据预估准确性的影响
  • 5
    SQL SERVER2005建Link Server
  • 6
    【代码分享-SQL】为DB中所有Table增加PK
  • 7
    SQL Server CLR 使用 C# 自定义存储过程和触发器
  • 8
    tempdb对SQL Server性能的影响 <转>
  • 9
    SQL SERVER 2012 执行计划走嵌套循环导致性能问题的案例
  • 10
    Sql Server在建好的表中，新增一列
  • 1
    SQL脚本相除
    70
  • 2
    0基础学习SQL注入之万能账号密码（BUUctf例题-[极客大挑战 2019]EasySQL1）
    660
  • 3
    SQL脚本利用带关联子查询Update语句更新数据
    135
  • 4
    10分钟了解Flink SQL使用
    390
  • 5
    SQL脚本把多行SQL数据变成一条多列数据
    118
  • 6
    mybatis动态sql
    44
  • 7
    基于若依的ruoyi-nbcio流程管理系统修改代码生成的sql菜单id修改成递增id（谨慎修改，大并发分布式有弊端）
    112
  • 8
    SQL脚本字符串替换
    72
  • 9
    你写的每条SQL都是全表扫描吗
    183
  • 10
    数据库SQL语言实战（六）
    54

    • 相关课程

    更多
  • 如何在 PolarDB-X 中优化慢 SQL
  • SQL完全自学手册
  • SQL Server on Linux入门教程
  • SQL入门与实践
  • 数据库及SQL/MySQL基础
  • SQL进阶及查询

    • 相关电子书

    更多
  • SQL Server在电子商务中的应用与实践
  • GeoMesa on Spark SQL
  • 原生SQL on Hadoop引擎- Apache HAWQ 2.x最新技术解密malili

    • 相关实验场景

    更多
  • PolarDB for AI：在数据库中通过SQL实现AI能力
  • 玩转MaxCompute SQL! 30分钟搞定数据分析挖掘
  • SQL进阶之约束、索引
  • SQL进阶之子句、关键字和操作符
  • 一小时快速掌握 SQL 语法
  • RDS MySQL的SQL问题诊断与调优
    • 下一篇
    fs.oss.accessKeyId和fs.oss.accessKeySecret。