开发者社区> 杰克.陈> 正文
阿里云
为了无法计算的价值
打开APP
阿里云APP内打开

Oracle基础 游标

简介: 原文:Oracle基础 游标 一、游标     游标用来处理从数据库中检索的多行记录(使用SELECT语句)。利用游标,程序可以逐个地处理和遍历一次检索返回的整个记录集。      为了处理SQL语句,Oracle将在内存中分配一个区域,这就是上下文区。
+关注继续查看
原文:Oracle基础 游标

一、游标  

  游标用来处理从数据库中检索的多行记录(使用SELECT语句)。利用游标,程序可以逐个地处理和遍历一次检索返回的整个记录集。

     为了处理SQL语句,Oracle将在内存中分配一个区域,这就是上下文区。这个区包含了已经处理完的行数、指向被分析语句的指针,整个区是查询语句返回的数据行集。游标就是指向上下文区句柄或指针。

 

二、游标的分类:

  1、静态游标:静态游标是在编译时知道其SELECT语句的游标。静态游标又分为两种类型,隐式游标和显示游标。

  2、动态游标:用户为游标使用的查询直到运行的时候才能确定,可以使用REF游标和游标变量满足这个要求。为了使用引用游标,必须声明游标变量。有两种类型的REF游标:强类型REF游标和弱类型REF游标。

 

 

三、显示游标的用法:

  显示游标被用于处理返回多行数据的SELECT 语句,游标名通过CURSOR….IS 语句显示地赋给SELECT 语句。

       (一)使用步骤;

       1)声明游标:CURSOR cursor_name IS select_statement

        2)为查询打开游标:OPEN cursor_name

        3)取得结果放入PL/SQL变量中;

                 FETCH cursor_name INTO list_of_variables;

               FETCH cursor_name INTO PL/SQL_record;

        4)关闭游标。CLOSE cursor_name

  注意:在声明游标时,select_statement不能包含INTO子句。当使用显示游标时,INTO子句是FETCH语句的一部分。

  例:显示雇员的名称和薪水

--使用LOOP遍历游标
DECLARE
  v_name emp.ename%TYPE;
  v_sal emp.sal%TYPE;
  CURSOR cus_emp IS
    SELECT ename,sal FROM emp;                         --声明游标
BEGIN
   OPEN cus_emp;                                       --打开游标
   LOOP 
      FETCH cus_emp INTO v_name,v_sal;                 --提取游标
      EXIT WHEN cus_emp%NOTFOUND;
      dbms_output.put_line(''||cus_emp%ROWCOUNT||'个用户:  name:'||v_name||'     sal:'||v_sal);
   END LOOP;
   CLOSE cus_emp;                                      --关闭游标
END;

  显示游标的属性:

  %FOUND:只有在DML语句影响一行或者多行是,则返回TRUE;

  %NOTFOUND:没有影响任何行,则返回TRUE。

  %ROWCOUNT:返回DML语句影响的行数,没有影响则返回0;

  %ISOPEN:返回游标是否打开,在执行SQL之后,Oracle自动关闭SQL游标,所以隐式游标的%isopen属性始终未false;

 

  另一种方式:

--使用for来简化游标遍历
DECLARE
  CURSOR cus_emp IS
    SELECT ename,sal FROM emp;
BEGIN
   FOR record_emp IN cus_emp
   LOOP 
      dbms_output.put_line(''||cus_emp%ROWCOUNT||'个用户:  name:'||record_emp.ename||'     sal:'||record_emp.sal);
   END LOOP;
END;

  record_emp是plsql声明的的记录变量,此变量的属性为声明为%ROWTYPE类型,作用域在FOR循环之内,即在FOR循环外就不能访问了。


  循环游标的特性:
  (1)从游标中提取了所有记录之后自动终止。
  (2)提取和处理游标中的每一条记录。
  (3)如果在提取记录之后%NOTFOUND属性返回TRUE,则终止循环。如果未返回任何行,则不进入循环。

 

游标案例:  

--给员工加薪,按员工入职时间进行加薪,每年加100,1000封顶
DECLARE
  v_date emp.hiredate%TYPE;
  v_empno emp.empno%TYPE;
  v_money NUMBER;
  CURSOR cur_emp IS
    SELECT empno,hiredate FROM emp;
BEGIN
  OPEN  cur_emp;
  LOOP
     FETCH cur_emp INTO v_empno,v_date;
     EXIT WHEN cur_emp%NOTFOUND;
     v_money := 100*(1990-to_char(v_date,'yyyy'));
     IF v_money<1000 THEN
        UPDATE emp SET sal=sal+v_money WHERE empno=v_empno;
     ELSE
        UPDATE emp SET sal=sal+1000 WHERE empno=v_empno;
     END IF;   
  END LOOP;
END;

 

四、隐式游标:

  所有的隐式游标都被假设为只返回一条记录。
  使用隐式游标时,用户无需进行声明、打开及关闭。PL/SQL隐含地打开、处理,然后关掉游标。多条sql语句 隐式游标SQL永远指的是最后一条sql语句的结果,主要使用在update 和 delete语句上。

  隐式游标的四个属性:

 

属性 说明
 SQL%rowcount  影响的记录的行数整数(用来判断插入,更新修改是否成功,必须在comit之前,否则提交后结果为0.)
 SQL%found  影响到了记录 true()
 SQL%notfound  没有影响到记录 true
 SQL%isopen  是否打开 布尔值 永远是false


例如:

DECLARE
  row_emp emp%ROWTYPE;
BEGIN
  SELECT ename,sal INTO row_emp.ename,row_emp.sal
  FROM emp WHERE emp.empno = 7369;
  --判断是否查到数据
  if(SQL%ROWCOUNT=1) THEN
    dbms_output.put_line('找到了');
  END IF;
  --另一种方式判断
  IF(SQL%Found) THEN
    dbms_output.put_line('找到了');
  END IF;

  dbms_output.put_line('ename:'||row_emp.ename||'    sal:'||row_emp.sal);
END;

 

上述游标自动打开,并把相关值赋给对应变量,然后关闭。执行完后,PL/SQL变量rowemp.ename,rowemp.sal中已经有了值。


五:动态游标

  静态游标是在声明就已经确定查询语句,如果用户需要在运行时动态决定游标执行的查询,就需要使用动态游标(REF游标)。

  动态游标分为两类:强类型游标弱类型游标

  动态游标使用步骤:

  1、声明动态游标类型;

  2、打开游标,指定游标查询;

  3、提取游标。

  4、关闭游标。

  例:

  强类型游标,使用return声明的游标为强类型游标。在对游标进行绑定查询只能绑定游标返回的类型rowtype。

--强类型的动态游标,查询emp表中的数据
DECLARE
  TYPE ref_cur IS REF CURSOR    --声明游标类型
  RETURN emp%ROWTYPE;       --带返回值的为强类型动态游标
  refcur_emp ref_cur;         --游标类型对象
  v_emp emp%ROWTYPE;
BEGIN
  OPEN refcur_emp FOR        --将游标绑定到一个查询语句,因为声明的是强类型,所以只能绑定emp;
    SELECT * FROM emp;    
  LOOP
    FETCH refcur_emp INTO v_emp;     --提取游标内容
    EXIT WHEN refcur_emp%NOTFOUND;
    dbms_output.put_line(refcur_emp%Rowcount||'、name:'||v_emp.ename||'    sal:'||v_emp.sal);
  END LOOP;
  CLOSE refcur_emp;
END;

  

  弱类型游标:可以用来绑定多个查询结果。

  例:

--弱类型游标
DECLARE
  TYPE refcur IS REF CURSOR;   --未定义返回类型为弱类型游标
  rc refcur;
  v_name emp.ename%TYPE;
  v_deptname dept.dname%TYPE;
BEGIN
  OPEN rc FOR SELECT ename,dname FROM emp e,dept d WHERE e.deptno = d.deptno;  --绑定查询
  LOOP
    FETCH rc INTO v_name,v_deptname;    
    EXIT WHEN rc%NOTFOUND;
    dbms_output.put_line('name:'||v_name||'               deptname:'||v_deptname);
  END LOOP;
  CLOSE rc;
END;

 

  例:

--根据输入的内容绑定游标
DECLARE 
  TYPE refcur IS REF CURSOR;
  rc refcur;
  v_tablename VARCHAR2(10) := '&tab';
  v_id NUMBER;
  v_name VARCHAR2(20);
BEGIN
  IF(v_tablename = 'e') THEN
    OPEN rc FOR 
      SELECT e.empno,e.ename INTO v_id,v_name FROM emp e;
      dbms_output.put_line('=========员工信息=============');
  Elsif(v_tablename = 'd') THEN
    OPEN rc FOR 
      SELECT d.deptno,d.dname INTO v_id,v_name FROM dept d;
      dbms_output.put_line('=========部门信息=============');
  ELSE
      dbms_output.put_line('输入错误,请输入e或者d!');
      RETURN;
  END IF;  
  
  LOOP 
    FETCH rc INTO v_id,v_name;
    dbms_output.put_line('#'||rc%Rowcount||'   id:'||v_id||'   name:'||v_name);
    EXIT WHEN rc%NOTFOUND;
  END LOOP;
END;

 

版权声明:本文内容由阿里云实名注册用户自发贡献,版权归原作者所有,阿里云开发者社区不拥有其著作权,亦不承担相应法律责任。具体规则请查看《阿里云开发者社区用户服务协议》和《阿里云开发者社区知识产权保护指引》。如果您发现本社区中有涉嫌抄袭的内容,填写侵权投诉表单进行举报,一经查实,本社区将立刻删除涉嫌侵权内容。

相关文章
Oracle 数据库性能优化3日实战(企业培训)
课程名称一: Oracle性能优化及调整 课程时长 1天 课程深度: 高级 上机实验: 10%-30% 授课对象: Oracle开发人员、Oracle数据库管理人员,应用程序开发人员 课程描述: 本课程讲述Oracle数据库物理层规划,系统性能的监控,数据库性能参数调整,统计信息的收集,使用自动化调试工具优化数据库,I/O子系统的配置与设计以及性能优化方法论等。
1824 0
[20141024]使用emacs连接使用oracle数据库
[20141024]使用emacs连接使用oracle数据库.txt --前一阵子跟别人学习了使用emacs连接数据库.自己做一个简单记录. 1.首先需要安装emacs.
935 0
Oracle 10g Express Edition(XE) 转至数据库主页中文乱码问题的解决
Oracle 10g Express Edition是Oracle专门为小型用户提供的免费版本。
886 0
+关注
杰克.陈
一个安静的程序猿~
10424
文章
2
问答
文章排行榜
最热
最新
相关电子书
更多
低代码开发师(初级)实战教程
立即下载
阿里巴巴DevOps 最佳实践手册
立即下载
冬季实战营第三期:MySQL数据库进阶实战
立即下载