unity噪声消融效果Shader实现

在 Unity 中实现噪声消融效果，主要是利用噪声纹理和透明度裁剪技术，通过噪声值来控制物体表面的显示与消失，从而达到消融的视觉效果。以下详细介绍其原理及相关实现要点：
基本概念
噪声纹理：噪声纹理是一种包含随机噪声信息的纹理，常见的有 Perlin 噪声、Simplex 噪声等。噪声纹理中的每个像素都有一个噪声值，这些值在一定范围内随机分布。在消融效果中，噪声纹理用于为物体表面的每个点提供一个随机的参考值，以此决定该点是否应该被消融。
透明度裁剪：透明度裁剪是一种渲染技术，通过设置一个透明度阈值，当物体表面某点的透明度低于该阈值时，该点将不会被渲染，从而实现物体部分消失的效果。
实现原理步骤

1. 引入噪声纹理
   首先，需要在着色器中引入噪声纹理。可以使用 Unity 自带的噪声纹理资源，或者通过代码生成自定义的噪声纹理。在着色器代码中，使用 sampler2D 类型的变量来采样噪声纹理。

shader代码如下：

Shader "Kaima/Dissolve/EdgeColor"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _NoiseTex("Noise", 2D) = "white" {}
        _Threshold("Threshold", Range(0.0, 1.0)) = 0.5
        _EdgeLength("Edge Length", Range(0.0, 0.2)) = 0.1
        _EdgeColor("Edge Color", Color) = (1,1,1,1)
    }
    SubShader
    {
        Tags { "Queue"="Geometry" "RenderType"="Opaque" }

        Pass
        {
            Cull Off //要渲染背面保证效果正确

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex : SV_POSITION;
                float2 uvMainTex : TEXCOORD0;
                float2 uvNoiseTex : TEXCOORD1;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _NoiseTex;
            float4 _NoiseTex_ST;
            float _Threshold;
            float _EdgeLength;
            fixed4 _EdgeColor;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uvMainTex = TRANSFORM_TEX(v.uv, _MainTex);
                o.uvNoiseTex = TRANSFORM_TEX(v.uv, _NoiseTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                //镂空
                fixed cutout = tex2D(_NoiseTex, i.uvNoiseTex).r;
                clip(cutout - _Threshold);

                //边缘颜色
                if(cutout - _Threshold < _EdgeLength)
                    return _EdgeColor;

                fixed4 col = tex2D(_MainTex, i.uvMainTex);
                return col;
            }
            ENDCG
        }
    }
}

新建材质球如下图

再加一张噪声贴图，如果嫌弃不好看可以自行替换