pro week_eleven_study1
  ; 如何批量制图
  ; tiff文件的路径
  tiff_dir = 'D:/IDL_program/experiment_data/chapter_6/TROPOMI_NO2/'
  ; 获取所有tiff文件的路径
  tiff_path_list = file_search(tiff_dir, '*.tiff', count=tiff_count)
  ; 获取所有tiff文件的名称
  tiff_name_list = file_basename(tiff_path_list, '.tiff')
  ; 获取shp文件的路径
  china_path = 'D:/IDL_program/experiment_data/chapter_6/shp_file/china_province.shp'
  sichuan_path = 'D:/IDL_program/experiment_data/chapter_6/shp_file/Sichuan_city_wgs84.shp'
  ; 据说使用beijing54坐标系有时会出现无法识别的现象，所以这里的shp文件是wgs84坐标系的
  ; 循环制图
  for tiff_i = 0, tiff_count - 1 do begin
    ; 获取该循环下的tiff文件的数据以及地理信息
    data = read_tiff(tiff_path_list[tiff_i], geotiff=geo_info)
    ; 输出路径
    out_path = tiff_dir + tiff_name_list[tiff_i] + '.png'
    ; 获取data的size
    data_size = size(data)
    ; 获取数据的行列数
    data_col = data_size[1]
    data_row = data_size[2]
    ; 获取图像数据的分辨率
    resolution = geo_info.(0)
    resolution_x = resolution[0]
    resolution_y = resolution[1]
    ; 获取图像数据的角点信息
    geo_loc = geo_info.(1)
    ; 最大最小经纬度
    lon_min = geo_loc[3]
    lat_max = geo_loc[4]
    lon_max = lon_min + data_col * resolution_x
    lat_min = lat_max - data_row * resolution_y
    ; 制图——》主要是image函数(我的意见是多看help)
    im = image($
      ; 为了方便解释，我会分行写代码并解释
      ; 首先传入制图需要的主体数据
      data,$
      $  
      ; 然后由于图像是黑白但是有灰度值，所以这里我们给他整个彩色
      rgb_table=22,$  ; 你可以写颜色渐变的代号(help里面有),也可以直接传入颜色字符串(譬如'red')
      ; 但是你可以发现这个颜色渐变有点离谱的那种感觉,所以你可能会想到去2%线性拉伸
      ; 但是没有必要，image()函数内置了min_value和max_value供您集中颜色
      min_value=0.0, max_value=0.002,$  ; 这些最大最小基于你自己在arcgis抑或envi查看得到(当然你可以写代码按某种2%的规则寻找)
      ; 由于我们的image函数是从下往上绘制图像，所以我们得到的图像是颠倒的，所以需要纠正
      /order,$
      ; 投影信息
      map_projection='Geographic',$  ; 你知道你的投影是什么之后去help查看输入即可
      ; 除此之外，你还应该告诉函数你的投影信息的单位是什么
      grid_units='degrees',$  ; 当然你也可以输入代号2(具体查看help)
      ; 但是只有上面的信息是不够的，函数不知道我们数据的地理位置，就算知道了投影也不知道把图片放在哪里
      ; 所以还需要告诉函数图像数据的位置(其实是告诉函数左下角点的经纬度)
      image_location=[lon_min, lat_min],$
      ; 另外，你还需要告诉函数x、y方向上跨越的经纬度度数(或者说是图像的尺寸)
      image_dimension=[lon_max - lon_min, lat_max - lat_min],$  ; 宽度和高度
      ; 上面是设置图像的大小尺寸，现在图像是要放在一个窗口中显示的，所以这里还需要设置一下窗口的大小(当然你不设置也是有默认的参数)
      dimension=[1000, 1000],$
      ; 另外有时候我们不需要那么大的图像显示在窗口中，那么我们可以通过输入最大最小经纬度限制显示的范围(这里我们设定只需要四川范围)
      limit=[25, 97.0, 35.0, 109.0],$  ; [Latmin, Lonmin, Latmax, Lonmax]
      ; 可能你现在会觉得四川范围的图像在窗口中显示的太小了，需要将图像在窗口中显示的大一些
      position=[0.05, 0.05, 0.95, 0.95])  ; [左下角点x、左下角点y、右上角点x、右上角点y]
      ; 这里传入的是图像左下角点和右上角点的坐标,这个坐标是图像的经纬度坐标，而是基于整个窗口的坐标，以窗口左下角点为(0, 0),右上角点为(1, 1)
      ; 那么去设置图像的左下角点和右上角点的坐标，就可以确定整幅图像在窗口的显示大小以及位置了
      ; 另外你可能会疑惑，我的图像长宽不是1：1，那么上面这样子会不会做拉伸处理，是不会的，函数会基于你给定的位置尽量靠近这个位置并放大，但是不会拉伸
    ; 现在设置好了image参数，可以往里面添加一些shp文件(不然孤零零的在那里一张图谁知道那地方是哪里啊)
    m1 = mapcontinents(china_path, color='black', linestyle='-:', thick=0.8)  ; 传入shp文件的路径(必须)
    ; 当然你也可以设置线的颜色color(不设置默认黑色)、线的样式linestyle(默认细实线)、设置线的厚度thick(当然还有一些其它的参数这里就不再一一介绍)
    m2 = mapcontinents(sichuan_path, color='black', linestyle='-', thick=1.8)
    ; 由于上面position我们知道函数是尽量在我们设置的位置放置图像，但是为了后续加上坐标轴之类的，那么我们就需要图像在窗口中的坐标位置了
    true_position = im.position
    position_dl_x = true_position[0]
    position_dl_y = true_position[1]
    position_ur_x = true_position[2]
    position_ur_y = true_position[3]
    ; 标题的相关设置
    ; 标题名称
    im.title = 'TROPOMI NO$_2$  result  over  Sichuan area'  ; 其中$$中间表示对其中的字符串进行特殊操作，这里_表示2是下标
    ; 标题的字体
    im.title.font_name = 'palatino'  ; 字体有哪些可以去help搜索font即可得到答案
    ; 字体的大小
    im.title.font_size = 16  ; 这个自己多试几下就知道字的大小了
    ; 字体颜色
    im.title.font_color = 'black'  ; 这里既可以传入颜色字符串，也可以传入RGB三个数字(以数组形式),更可以传入颜色的代称(但是不是1、2诸如此类，而是#加一些数字，具体代表什么颜色看help)
    ; 字体的粗细
    im.title.font_style = 3  ; 表示粗体(0-正常\2-斜体\3-斜粗体)，另外也可以传入字符串达到相同的效果，具体看help
    ; 格网的相关设置
    ; 格网对象设置(其实前面标题也是可以这样设置，如果你学过诸如python之类面向对象语言，那么相信这是很容易理解的)
    grid = im.mapgrid
    ; 我们看图片可以发现，经纬度显示在格网的线上，而不是在图的侧边，为了我们的视觉习惯，我们可以更改
    grid.label_position = 0  ; 其实这里你可以设置[0,1](闭区间)、0表示最靠左最靠下，1表示最靠右最靠上，处于中间按比例靠近
    ; 因为这里有每一条经纬线的标签，所以也是可以有字体的相关设置的
    grid.font_name = 'schoolbook'  ; 我随便在help挑的一种字体
    grid.font_size = 8  ; 这个在轴上显示的应该比上面的title下一点才是
;    grid.font_color = 'black'  ; 我只是告诉大家这个也是有的，都是相通的，其实不写默认也是黑色的(我错了，这个是没有的，所以大家要多多尝试，勇于犯错)
    grid.font_style = 'bi'  ; 这里是告诉，上面可以使用1、2类似的数字，这里使用字符串也是可以达到相同的效果(bi是粗体斜体)
    ; 设置格网线的样式(我们觉得这个格网线是实线有点喧宾夺主，所以换成虚线会比较好一点)
    grid.linestyle = '-.'  ; __表示虚线，其它还有一些表示可以自行查看·help
    ; 对于格网的最外边的一圈线，我们觉得粗细不对，应该再设置的粗一点，不应当和里面的线是虚线而且那么细
    grid.horizon_thick = 2  ; 我们如果设置了这个那么会将horizon line(最外圈的线)更改为实线,如果你还有修改horizon line的需求，可以指定grid.horizon_linestyle
    ; 得到经度标签的对象
    lons = grid.longitudes
    lats = grid.latitudes
    ; 我们的x轴的标签是竖着的，我们希望是横着的(由于lons是对象类型的数组，里面是每一个标签对象,所以需要循环)
    for lon_i = 0, n_elements(lons) - 1 do lons[lon_i].label_angle = 0.0  ; 旋转角度是0表示没有旋转就是横着的
    for lat_i = 0, n_elements(lats) - 1 do lats[lat_i].label_angle = 90.0  ; 另外我们希望y轴的标签是竖着的，所以旋转角度是90°
    ; 另外我们发现在原点处的标签重合了，所以我们需要再设置一下标签的对齐方式(默认是居中对齐)(其实这个可以写到上面循环中去)
    for lon_i = 0, n_elements(lons) - 1 do lons[lon_i].label_align = 0.0  ; 0.0表示左对齐，0.5表示中间对齐，1.0表示右对齐，其它0-1的数字按比例对齐
    for lat_i = 0, n_elements(lats) - 1 do lats[lat_i].label_align = 0.0
    ; 然后还有就是x轴和y轴最后一个表示经纬度的标签有点多余，我们需要将其隐藏
    lons[-1].label_show = 0  ; 0表示隐藏
    lats[-1].label_show = 0  ; -1表示最后一个数字
    ; 另外我们希望在指定的位置写上地名之类的东西，那么这个在idl是比较麻烦的，好像目前没有别的办法
    ; 这里解释第一个:首先传入经纬度(先x轴坐标再y轴坐标，然后传入需要填写的值，在之后传入填写的位置,在后面的参数就是微调)
    t=text(103.3d,30.46d,'Chengdu',/data,$
      font_name='Palatino',font_size=12, font_style=1)  ; 省会城市我们让其粗体好了
    t=text(101.8d,31.8d,'Aba',/data,$
      font_name='Palatino',font_size=12)
    t=text(100.1d,31.5d,'Ganzi',/data,$
      font_name='Palatino',font_size=12)
    t=text(101.6d,27.65d,'Liangshan',/data,$
      font_name='Palatino',font_size=12)
    t=text(101.1d,26.7d,'Panzhihua',/data,$
      font_name='Palatino',font_size=12)
    t=text(102.5d,29.8d,'Yaan',/data,$
      font_name='Palatino',font_size=12)
    t=text(104.0d,30.93d,'Deyang',/data,$
      font_name='Palatino',font_size=12)
    t=text(104.1d,31.6d,'Mianyang',/data,$
      font_name='Palatino',font_size=12)
    t=text(105.2d,28.65d,'Luzhou',/data,$
      font_name='Palatino',font_size=12)
    t=text(103.4d,29.8d,'Meishan',/data,$
      font_name='Palatino',font_size=12)
    t=text(104.75d,30.05d,'Ziyang',/data,$
      font_name='Palatino',font_size=12)
    t=text(104.5d,29.7d,'Neijiang',/data,$
      font_name='Palatino',font_size=12)
    t=text(104.3d,29.15d,'Zigong',/data,$
      font_name='Palatino',font_size=12)
    t=text(104.4d,28.5d,'Yibin',/data,$
      font_name='Palatino',font_size=12)
    t=text(105.0d,30.6d,'Suining',/data,$
      font_name='Palatino',font_size=12)
    t=text(105.7d,30.88d,'Nanchong',/data,$
      font_name='Palatino',font_size=12)
    t=text(107.2d,31.3d,'Dazhou',/data,$
      font_name='Palatino',font_size=12)
    t=text(106.1d,30.25d,'Guangan',/data,$
      font_name='Palatino',font_size=12)
    t=text(106.5d,31.95d,'Bazhong',/data,$
      font_name='Palatino',font_size=12)
    t=text(105.3d,32.2d,'Guangyuan',/data,$
      font_name='Palatino',font_size=12)
    t=text(103.4d,29.3d,'Leshan',/data,$
      font_name='Palatino',font_size=12)
    ; 另外还有城市的symbol，图形符号也搞一个(当然，这个也是费时费力)
    s=symbol(104.06d,30.67d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=2)  ; 成都的符号就粗一点把
    s=symbol(101.72d,31.93d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(99.96d,31.64d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(102.27d,27.90d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(101.72d,26.58d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(103.00d,29.98d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(104.38d,31.13d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(104.73d,31.47d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(105.43d,28.87d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(103.83d,30.05d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(104.65d,30.12d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(105.05d,29.58d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(104.78d,29.35d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(104.62d,28.77d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(105.57d,30.52d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(106.08d,30.78d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(107.50d,31.22d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(106.63d,30.47d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(106.77d,31.85d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(105.83d,32.43d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    s=symbol(103.77d,29.57d,'circle',/data,$
      sym_size=0.5,sym_color='black',sym_thick=1.5)
    ; 现在图还缺一点什么呢？对了，还有图例没有
    cb = colorbar(/data, target=im)
    ; 由于空间有限，所以我们需要将图标移动到左下角的位置(上面colorbar函数默认显示在图的正底下)
    cb.position = [position_dl_x + 0.5, position_dl_y - 0.07, position_ur_x, 0.09]  ; 这个需要自己慢慢调
    ; 另外图例的数字位数太多，也需要调整一下
    cb.range = [0.00, 1.00]
    ; 做好了图标总要告诉人家这个图标是什么吧？还缺个标题或者说是单位，我们前面将0.001改为了1.0，所以要有标题提醒10^-3
    cb.title = 'NO$_2$ ($\times$10$^{-3}$ mol / m$^2$)'  ; ✖是特殊符号，help里面有对应的写法，这里\times表示乘号
    cb.font_style = 2  ; 设置为斜体
    ; 另外还有城市图标那个图例没有弄
    s=symbol(position_dl_x+0.2,position_dl_y-0.07,'circle',target=im,$
      sym_size=0.6,sym_color='black',sym_thick=1.5)
    t=text(position_dl_x+0.21,position_dl_y-0.07,'City center',target=im,$
      font_name='Palatino',font_size=12)
    ; 保存图片
    im.save, out_path
    ; 关闭弹出的图片
    im.close
  print
  endfor
end